[arch-commits] Commit in vlc/repos (4 files)

Jan Steffens heftig at archlinux.org
Sun Feb 24 22:55:04 UTC 2019


    Date: Sunday, February 24, 2019 @ 22:55:03
  Author: heftig
Revision: 346775

archrelease: copy trunk to testing-x86_64

Added:
  vlc/repos/testing-x86_64/
  vlc/repos/testing-x86_64/PKGBUILD
    (from rev 346774, vlc/trunk/PKGBUILD)
  vlc/repos/testing-x86_64/lua53_compat.patch
    (from rev 346774, vlc/trunk/lua53_compat.patch)
  vlc/repos/testing-x86_64/update-vlc-plugin-cache.hook
    (from rev 346774, vlc/trunk/update-vlc-plugin-cache.hook)

------------------------------+
 PKGBUILD                     |  243 +++++++++++++++++++++++++++++++++++++++++
 lua53_compat.patch           |   30 +++++
 update-vlc-plugin-cache.hook |   11 +
 3 files changed, 284 insertions(+)

Copied: vlc/repos/testing-x86_64/PKGBUILD (from rev 346774, vlc/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-02-24 22:55:03 UTC (rev 346775)
@@ -0,0 +1,243 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sarah Hay <sarahhay at mb.sympatico.ca>
+# Contributor: Martin Sandsmark <martin.sandsmark at kde.org>
+
+pkgname=vlc
+_vlcver=3.0.6
+# optional fixup version including hyphen
+_vlcfixupver=
+pkgver=${_vlcver}${_vlcfixupver//-/.r}
+pkgrel=4
+pkgdesc='Multi-platform MPEG, VCD/DVD, and DivX player'
+url='https://www.videolan.org/vlc/'
+arch=('x86_64')
+license=('LGPL2.1' 'GPL2')
+depends=('a52dec' 'libdvbpsi' 'libxpm' 'libdca' 'libproxy' 'lua' 'libidn'
+         'libmatroska' 'taglib' 'libmpcdec' 'ffmpeg' 'faad2' 'libupnp' 'libmad'
+         'libmpeg2' 'xcb-util-keysyms' 'libtar' 'libxinerama' 'libsecret'
+         'libarchive' 'qt5-base' 'qt5-x11extras' 'qt5-svg' 'freetype2'
+         'fribidi' 'harfbuzz' 'fontconfig' 'libxml2' 'gnutls' 'libplacebo'
+         'wayland-protocols' 'aribb24')
+makedepends=('gst-plugins-base-libs' 'live-media' 'libnotify' 'libbluray'
+             'flac' 'libdc1394' 'libavc1394' 'libcaca' 'gtk3'
+             'librsvg' 'libgme' 'xosd' 'twolame' 'aalib' 'avahi' 'systemd-libs'
+             'libmtp' 'libupnp' 'libmicrodns' 'libdvdcss' 'smbclient'
+             'vcdimager' 'libssh2' 'mesa' 'protobuf' 'libnfs' 'mpg123'
+             'libdvdread' 'libdvdnav' 'libogg' 'libshout' 'libmodplug' 'libvpx'
+             'libvorbis' 'speex' 'opus' 'libtheora' 'libpng' 'libjpeg-turbo'
+             'libx265.so' 'libx264.so' 'zvbi' 'libass' 'libkate' 'libtiger'
+             'sdl_image' 'libpulse' 'alsa-lib' 'jack' 'libsamplerate' 'libsoxr'
+             'lirc' 'libgoom2' 'projectm' 'chromaprint' 'aom' 'srt' 'dav1d')
+optdepends=('avahi: service discovery using bonjour protocol'
+            'aom: AOM AV1 codec'
+            'gst-plugins-base-libs: for libgst plugins'
+            'dav1d: dav1d AV1 decoder'
+            'libdvdcss: decoding encrypted DVDs'
+            'libavc1394: devices using the 1394ta AV/C'
+            'libdc1394: IEEE 1394 access plugin'
+            'kwallet: kwallet keystore'
+            'libva-vdpau-driver: vdpau backend nvidia'
+            'libva-intel-driver: video backend intel'
+            'libbluray: Blu-Ray video input'
+            'flac: Free Lossless Audio Codec plugin'
+            'twolame: TwoLAME mpeg2 encoder plugin'
+            'libgme: Game Music Emu plugin'
+            'vcdimager: navigate VCD with libvcdinfo'
+            'libmtp: MTP devices discovery'
+            'systemd-libs: udev services discovery'
+            'smbclient: SMB access plugin'
+            'libcdio: audio CD playback'
+            'ttf-freefont: subtitle font '
+            'ttf-dejavu: subtitle font'
+            'libssh2: sftp access'
+            'libnfs: NFS access'
+            'mpg123: mpg123 codec'
+            'protobuf: chromecast streaming'
+            'libmicrodns: mDNS services discovery (chromecast etc)'
+            'lua-socket: http interface'
+            'live-media: RTSP input'
+            'libdvdread: DVD input module'
+            'libdvdnav: DVD with navigation input module'
+            'libogg: Ogg and OggSpots codec'
+            'libshout: shoutcast/icecast output plugin'
+            'libmodplug: MOD output plugin'
+            'libvpx: VP8 and VP9 codec'
+            'libvorbis: Vorbis decoder/encoder'
+            'speex: Speex codec'
+            'opus: opus codec'
+            'libtheora: theora codec'
+            'libpng: PNG support'
+            'libjpeg-turbo: JPEG support'
+            'librsvg: SVG plugin'
+            'x264: H264 encoding'
+            'x265: HEVC/H.265 encoder'
+            'zvbi: VBI/Teletext decoding'
+            'libass: Subtitle support'
+            'libkate: Kate codec'
+            'libtiger: Tiger rendering for Kate streams'
+            'sdl_image: SDL image support'
+            'srt: SRT input/output plugin'
+            'aalib: ASCII art video output'
+            'libcaca: colored ASCII art video output'
+            'libpulse: PulseAudio audio output'
+            'alsa-lib: ALSA audio output'
+            'jack: jack audio server'
+            'libsamplerate: audio Resampler'
+            'libsoxr: SoX audio Resampler'
+            'chromaprint: Chromaprint audio fingerprinter'
+            'lirc: lirc control'
+            'libgoom2: Goom visualization'
+            'projectm: ProjectM visualisation'
+            'ncurses: ncurses interface'
+            'libnotify: notification plugin'
+            'gtk3: notification plugin')
+conflicts=('vlc-plugin')
+replaces=('vlc-plugin')
+options=('!emptydirs')
+source=(https://download.videolan.org/${pkgname}/${_vlcver}/${pkgname}-${_vlcver}${_vlcfixupver}.tar.xz{,.asc}
+        update-vlc-plugin-cache.hook
+        lua53_compat.patch)
+sha512sums=('7c72e98f30ce5c5a94d74e097fa9960442f89240079b042a729f8a33dd7fedee2538c86c99738ccef2eb27f29055f0221d4c70316e3312c5ebba9565eaa15c52'
+            'SKIP'
+            '80357bae69e32b353d3784932d854e294906798e14faffb87c3383c3b6f6bdc57cbabb9c6e3f3c1adf0f8ddbb24153e72104c963cf1934970c2983c96daef9df'
+            '33cda373aa1fb3ee19a78748e2687f2b93c8662c9fda62ecd122a2e649df8edaceb54dda3991bc38c80737945a143a9e65baa2743a483bb737bb94cd590dc25f')
+validpgpkeys=('65F7C6B4206BD057A7EB73787180713BE58D1ADC') # VideoLAN Release Signing Key
+
+prepare() {
+  cd ${pkgname}-${_vlcver}
+  sed -e 's:truetype/ttf-dejavu:TTF:g' -i modules/visualization/projectm.cpp
+  sed -e 's|-Werror-implicit-function-declaration||g' -i configure
+  sed 's|whoami|echo builduser|g' -i configure
+  sed 's|hostname -f|echo arch|g' -i configure
+  local src
+  for src in "${source[@]}"; do
+    src="${src%%::*}"
+    src="${src##*/}"
+    [[ $src = *.patch ]] || continue
+    msg2 "Applying patch $src..."
+    patch -Np1 < "../$src"
+  done
+}
+
+build() {
+  cd ${pkgname}-${_vlcver}
+
+  export CFLAGS+=" -I/usr/include/samba-4.0"
+  export CPPFLAGS+=" -I/usr/include/samba-4.0"
+  export CXXFLAGS+=" -std=c++11"
+  export LUAC=/usr/bin/luac
+  export LUA_LIBS="$(pkg-config --libs lua)"
+  export RCC=/usr/bin/rcc-qt5
+
+  ./configure --prefix=/usr \
+              --sysconfdir=/etc \
+              --with-kde-solid=/usr/share/solid/actions/ \
+              --disable-rpath \
+              --enable-nls \
+              --enable-archive \
+              --enable-live555 \
+              --enable-dc1394 \
+              --enable-dv1394 \
+              --enable-dvdread \
+              --enable-dvdnav \
+              --enable-bluray \
+              --disable-opencv \
+              --enable-smbclient \
+              --enable-sftp \
+              --enable-nfs \
+              --enable-realrtsp \
+              --enable-dvbpsi \
+              --enable-gme \
+              --enable-ogg \
+              --enable-shout \
+              --enable-matroska \
+              --enable-mod \
+              --enable-mpc \
+              --enable-mad \
+              --enable-mpg123 \
+              --enable-gst-decode \
+              --enable-avcodec \
+              --enable-libva \
+              --enable-avformat \
+              --enable-postproc \
+              --enable-faad \
+              --enable-vpx \
+              --enable-twolame \
+              --disable-fdkaac \
+              --enable-a52 \
+              --enable-dca \
+              --enable-flac \
+              --enable-libmpeg2 \
+              --enable-vorbis \
+              --enable-speex \
+              --enable-opus \
+              --enable-oggspots \
+              --disable-schroedinger \
+              --enable-png \
+              --enable-jpeg \
+              --enable-x264 \
+              --enable-x265 \
+              --enable-zvbi \
+              --enable-libass \
+              --enable-kate \
+              --enable-tiger \
+              --enable-vdpau \
+              --enable-wayland \
+              --enable-sdl-image \
+              --enable-freetype \
+              --enable-fribidi \
+              --enable-harfbuzz \
+              --enable-fontconfig \
+              --enable-svg \
+              --enable-svgdec \
+              --enable-aa \
+              --enable-caca \
+              --enable-pulse \
+              --enable-alsa \
+              --enable-jack \
+              --enable-samplerate \
+              --enable-soxr \
+              --enable-chromaprint \
+              --enable-chromecast \
+              --enable-qt \
+              --enable-skins2 \
+              --enable-libtar \
+              --enable-ncurses \
+              --enable-lirc \
+              --enable-goom \
+              --enable-projectm \
+              --enable-avahi \
+              --enable-mtp \
+              --enable-upnp \
+              --enable-microdns \
+              --enable-libxml2 \
+              --disable-libgcrypt \
+              --enable-gnutls \
+              --enable-taglib \
+              --enable-secret \
+              --enable-kwallet \
+              --disable-update-check \
+              --enable-notify \
+              --enable-libplacebo \
+              --enable-vlc \
+              --enable-aribsub \
+              --enable-aom \
+              --enable-srt
+              #--enable-dav1d \
+  make
+}
+
+package() {
+  cd ${pkgname}-${_vlcver}
+
+  make DESTDIR="${pkgdir}" install
+
+  for res in 16 32 48 128 256; do
+    install -Dm 644 "${srcdir}/vlc-${_vlcver}/share/icons/${res}x${res}/vlc.png" \
+                     "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
+  done
+  install -Dm 644 "${srcdir}/update-vlc-plugin-cache.hook" -t "${pkgdir}/usr/share/libalpm/hooks"
+}
+
+# vim: ts=2 sw=2 et:

Copied: vlc/repos/testing-x86_64/lua53_compat.patch (from rev 346774, vlc/trunk/lua53_compat.patch)
===================================================================
--- testing-x86_64/lua53_compat.patch	                        (rev 0)
+++ testing-x86_64/lua53_compat.patch	2019-02-24 22:55:03 UTC (rev 346775)
@@ -0,0 +1,30 @@
+commit 41caaa08cde60c4fec4bf2e5f9610e2a1b9e6a23
+Author: Vinson Lee <vlee at freedesktop.org>
+Date:   Thu Feb 5 14:48:53 2015 -0800
+
+    lua: Define LUA_COMPAT_APIINTCASTS for Lua >= 5.3.0 compatibility.
+    
+    In Lua 5.3.0, luaL_checkint was deprecated.
+    
+    This patch fixes this build error with Lua 5.3.0.
+    
+    lua/demux.c: In function ‘vlclua_demux_peek’:
+    lua/demux.c:55:5: error: implicit declaration of function ‘luaL_checkint’ [-Werror=implicit-function-declaration]
+         int n = luaL_checkint( L, 1 );
+         ^
+    
+    Signed-off-by: Vinson Lee <vlee at freedesktop.org>
+    Signed-off-by: Jean-Baptiste Kempf <jb at videolan.org>
+
+diff --git a/modules/lua/vlc.h b/modules/lua/vlc.h
+index efd94f1..85c7fc1 100644
+--- a/modules/lua/vlc.h
++++ b/modules/lua/vlc.h
+@@ -38,6 +38,7 @@
+ #include <vlc_stream.h>
+ #include <vlc_demux.h>
+ 
++#define LUA_COMPAT_APIINTCASTS
+ #define LUA_COMPAT_MODULE
+ #include <lua.h>        /* Low level lua C API */
+ #include <lauxlib.h>    /* Higher level C API */

Copied: vlc/repos/testing-x86_64/update-vlc-plugin-cache.hook (from rev 346774, vlc/trunk/update-vlc-plugin-cache.hook)
===================================================================
--- testing-x86_64/update-vlc-plugin-cache.hook	                        (rev 0)
+++ testing-x86_64/update-vlc-plugin-cache.hook	2019-02-24 22:55:03 UTC (rev 346775)
@@ -0,0 +1,11 @@
+[Trigger]
+Type = File
+Operation = Install
+Operation = Upgrade
+Operation = Remove
+Target = usr/lib/vlc/plugins/*
+
+[Action]
+Description = Updating the vlc plugin cache...
+When = PostTransaction
+Exec = /usr/lib/vlc/vlc-cache-gen /usr/lib/vlc/plugins



More information about the arch-commits mailing list