[arch-commits] Commit in python-msgpack/repos (2 files)
Johannes Löthberg
demize at archlinux.org
Tue Jan 1 17:55:43 UTC 2019
Date: Tuesday, January 1, 2019 @ 17:55:42
Author: demize
Revision: 420197
archrelease: copy trunk to community-testing-x86_64
Added:
python-msgpack/repos/community-testing-x86_64/
python-msgpack/repos/community-testing-x86_64/PKGBUILD
(from rev 420196, python-msgpack/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: python-msgpack/repos/community-testing-x86_64/PKGBUILD (from rev 420196, python-msgpack/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2019-01-01 17:55:42 UTC (rev 420197)
@@ -0,0 +1,52 @@
+# Maintainer: Johannes Löthberg <johannes at kyriasis.com>
+# Contributor: Sébastien "Seblu" Luttringer
+
+pkgbase=python-msgpack
+pkgname=('python-msgpack' 'python2-msgpack')
+pkgver=0.6.0
+pkgrel=1
+
+url='https://github.com/msgpack/msgpack-python'
+arch=('x86_64')
+license=('Apache')
+
+makedepends=('cython' 'cython2' 'python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest' 'python2-pytest' 'python-six' 'python2-six')
+
+source=(msgpack-python-$pkgver.tar.gz::https://github.com/msgpack/msgpack-python/archive/v$pkgver.tar.gz)
+
+md5sums=('4b1c5db81133f9992179aa773e6ed3a0')
+
+build() {
+ cd msgpack-python-$pkgver
+ python setup.py build --build-lib=build/python
+ python2 setup.py build --build-lib=build/python2
+ find build/python2 -type f -exec \
+ sed -i '1s,^#! \?/usr/bin/\(env \|\)python$,#!/usr/bin/python2,' {} \;
+}
+
+check() {
+ cd msgpack-python-$pkgver
+ PYTHONPATH=$PWD/build/python py.test test
+ PYTHONPATH=$PWD/build/python2 py.test2 test
+}
+
+package_python-msgpack() {
+ pkgdesc='MessagePack serializer implementation for Python'
+ depends=('python')
+
+ cd msgpack-python-$pkgver
+ python setup.py build --build-lib=build/python \
+ install --root="$pkgdir" --optimize=1
+}
+
+package_python2-msgpack() {
+ pkgdesc='MessagePack serializer implementation for Python2'
+ depends=('python2')
+
+ cd msgpack-python-$pkgver
+ python2 setup.py build --build-lib=build/python2 \
+ install --root="$pkgdir" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list