[arch-commits] Commit in snd/repos (2 files)

[Evangelos Foutras]

    Date: Monday, January 7, 2019 @ 01:31:59
  Author: foutrelis
Revision: 420911

archrelease: copy trunk to community-staging-x86_64

Added:
  snd/repos/community-staging-x86_64/
  snd/repos/community-staging-x86_64/PKGBUILD
    (from rev 420910, snd/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: snd/repos/community-staging-x86_64/PKGBUILD (from rev 420910, snd/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-01-07 01:31:59 UTC (rev 420911)
@@ -0,0 +1,51 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+# Contributor: see .contrib
+
+pkgname=snd
+pkgver=18.9
+pkgrel=2
+pkgdesc="An advanced sound editor"
+arch=('x86_64')
+url="https://ccrma.stanford.edu/software/snd/"
+license=('custom:free')
+groups=('pro-audio')
+depends=('fftw' 'gsl' 'gtk3' 'jack' 'libmpc' 'ruby')
+makedepends=('flac' 'gmp' 'glu' 'ladspa' 'libpulse' 'libxpm' 'mpg123'
+'openmotif' 'speex' 'timidity++' 'vorbis-tools' 'wavpack')
+optdepends=('wavpack: For wav support'
+            'flac: For flac support'
+            'speex: For speex support'
+            'mpg123: For MPEG support'
+            'pulseaudio: For pulseaudio support'
+            'timidity++: For MIDI to WAVE support'
+            'vorbis-tools: For OGG support')
+source=("https://sourceforge.net/projects/${pkgname}/files/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('a6f674a078674e68be566f4676222d247f7a316ddb756d2cfe3470f5524b26b2d6df450ef562e137ed28d7a30e197cd0550cab8e22ec0b6a9f87d297a15e39ae')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  ./configure --prefix=/usr \
+              --with-alsa \
+              --with-gmp \
+              --with-gtk \
+              --with-jack \
+              --with-ladspa \
+              --with-pulseaudio \
+              --with-ruby
+  make
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  make prefix="${pkgdir}/usr" install
+  install -vDm 644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+  # docs
+  install -vDm 644 {{HISTORY,README}.Snd,NEWS} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/"
+  install -vDm 644 *.html -t "${pkgdir}/usr/share/doc/${pkgname}/html"
+  install -vDm 644 pix/*.png -t "${pkgdir}/usr/share/doc/${pkgname}/html/pix"
+}
+
+# vim:set ts=2 sw=2 et: