[arch-commits] Commit in haskell-servant-swagger/repos (2 files)

Felix Yan felixonmars at archlinux.org
Thu Jan 10 16:08:05 UTC 2019


    Date: Thursday, January 10, 2019 @ 16:08:04
  Author: felixonmars
Revision: 421885

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant-swagger/repos/community-staging-x86_64/
  haskell-servant-swagger/repos/community-staging-x86_64/PKGBUILD
    (from rev 421884, haskell-servant-swagger/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-servant-swagger/repos/community-staging-x86_64/PKGBUILD (from rev 421884, haskell-servant-swagger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-01-10 16:08:04 UTC (rev 421885)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant-swagger
+pkgname=haskell-servant-swagger
+pkgver=1.1.6
+pkgrel=12
+pkgdesc="Generate Swagger specification for your servant API."
+url="https://github.com/haskell-servant/servant-swagger"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-http-media'
+         'haskell-insert-ordered-containers' 'haskell-lens' 'haskell-servant'
+         'haskell-singleton-bool' 'haskell-swagger2' 'haskell-unordered-containers'
+         'haskell-hspec' 'haskell-quickcheck')
+makedepends=('ghc' 'haskell-base-compat' 'haskell-cabal-doctest' 'haskell-doctest'
+             'haskell-hspec-discover' 'haskell-utf8-string')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7110d4b4953815f1e70d48476ec47a2d113c18e0012fecd34982fc3f205313595e49a2fe07b783d6565428d9e69e971ffa59ebe16810e057a45782cb47c373e6')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test || warning "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list