[arch-commits] Commit in ardour/repos (3 files)

Evangelos Foutras foutrelis at archlinux.org
Fri Jan 11 07:35:59 UTC 2019


    Date: Friday, January 11, 2019 @ 07:35:59
  Author: foutrelis
Revision: 422250

archrelease: copy trunk to community-staging-x86_64

Added:
  ardour/repos/community-staging-x86_64/
  ardour/repos/community-staging-x86_64/.contrib
    (from rev 422249, ardour/trunk/.contrib)
  ardour/repos/community-staging-x86_64/PKGBUILD
    (from rev 422249, ardour/trunk/PKGBUILD)

----------+
 .contrib |    2 ++
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

Copied: ardour/repos/community-staging-x86_64/.contrib (from rev 422249, ardour/trunk/.contrib)
===================================================================
--- community-staging-x86_64/.contrib	                        (rev 0)
+++ community-staging-x86_64/.contrib	2019-01-11 07:35:59 UTC (rev 422250)
@@ -0,0 +1,2 @@
+# Contributor: Bernardo Barros <bernardobarros at gmail.com>
+# Contributor: Uli Armbruster <uli_armbruster at web.de>

Copied: ardour/repos/community-staging-x86_64/PKGBUILD (from rev 422249, ardour/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-01-11 07:35:59 UTC (rev 422250)
@@ -0,0 +1,55 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: SpepS <dreamspepser at yahoo dot it>
+
+_name=Ardour
+pkgname=ardour
+pkgver=5.12
+pkgrel=10
+pkgdesc="Professional-grade digital audio workstation"
+arch=('x86_64')
+url="https://ardour.org/"
+license=('GPL')
+groups=('pro-audio')
+depends=('liblrdf' 'libarchive' 'liblo' 'lilv' 'suil' 'taglib' 'aubio'
+'rubberband' 'gtkmm')
+makedepends=('boost' 'cppunit' 'git' 'itstool' 'python2')
+optdepends=('xjadeo: video monitoring'
+            'harvid: video timeline')
+source=("${pkgname}-${pkgver}::git+https://github.com/${pkgname}/${pkgname}.git#tag=${pkgver}")
+sha512sums=('SKIP')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python2 waf configure --prefix=/usr \
+                        --configdir=/etc \
+                        --with-backends="jack,alsa,dummy" \
+                        --libjack=weak \
+                        --nls \
+                        --optimize \
+                        --cxx11 \
+                        --freedesktop \
+                        --ptformat \
+                        --lxvst \
+                        --no-phone-home
+  python2 waf build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  python2 waf i18n --destdir="${pkgdir}"
+  python2 waf install --destdir="${pkgdir}"
+  # xdg integration
+  install -vDm 644 "build/gtk2_${pkgname}/${pkgname}.xml" \
+    -t "${pkgdir}/usr/share/mime/packages/"
+  install -vDm 644 "build/gtk2_${pkgname}/${pkgname}${pkgver%%.*}.desktop" \
+    "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  for size in 16 22 32 48 256 512; do
+    install -vDm 644 "gtk2_${pkgname}/resources/${_name}-icon_${size}px.png" \
+      "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/${pkgname}${pkgver%%.*}.png"
+  done
+  # man pages
+  install -vDm 644 "${pkgname}.1"* -t "${pkgdir}/usr/share/man/man1/"
+}
+
+# vim:set ts=2 sw=2 et:


More information about the arch-commits mailing list