[arch-commits] Commit in bochs/repos (2 files)

[Felix Yan]

    Date: Friday, January 11, 2019 @ 07:54:40
  Author: felixonmars
Revision: 422291

archrelease: copy trunk to community-staging-x86_64

Added:
  bochs/repos/community-staging-x86_64/
  bochs/repos/community-staging-x86_64/PKGBUILD
    (from rev 422290, bochs/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: bochs/repos/community-staging-x86_64/PKGBUILD (from rev 422290, bochs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-01-11 07:54:40 UTC (rev 422291)
@@ -0,0 +1,56 @@
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
+# Contributor: Kevin Piche <kevin at archlinux.org>
+
+pkgname=bochs
+pkgver=2.6.9
+pkgrel=3
+pkgdesc="A portable x86 PC emulation software package, including GUI debugger"
+arch=('x86_64')
+url="http://bochs.sourceforge.net/"
+license=('LGPL')
+depends=('gcc-libs' 'libxrandr' 'libxpm' 'gtk2')
+source=("https://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz")
+md5sums=('f6670c56ac49af36174e254e82528d5f')
+
+prepare() {
+    cd "$srcdir/$pkgname-$pkgver"
+    # 4.X kernel is basically 3.20
+    sed -i 's/2\.6\*|3\.\*)/2.6*|3.*|4.*)/' configure*
+}
+
+build() {
+    cd "$srcdir/$pkgname-$pkgver"
+
+    ./configure \
+        --prefix=/usr \
+        --without-wx \
+        --with-x11 \
+        --with-x \
+        --with-term \
+        --disable-docbook \
+        --enable-cpu-level=6 \
+        --enable-fpu \
+        --enable-3dnow \
+        --enable-disasm \
+        --enable-smp \
+        --enable-x86-64 \
+        --enable-avx \
+        --enable-long-phy-address \
+        --enable-disasm \
+        --enable-pcidev \
+        --enable-usb \
+        --enable-debugger
+        #--with-sdl
+        #--enable-x86-debugger
+        #--enable-all-optimizations
+        #--enable-plugins
+    sed -i 's/^LIBS = /LIBS = -lpthread/g' Makefile
+    make -j 1
+}
+
+package() {
+    cd "$srcdir/$pkgname-$pkgver"
+    make DESTDIR="$pkgdir" install
+    install -Dm644 .bochsrc "$pkgdir/etc/bochsrc-sample.txt"
+}