[arch-commits] Commit in curl/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Sunday, January 13, 2019 @ 19:39:24
  Author: felixonmars
Revision: 343981

archrelease: copy trunk to staging-x86_64

Added:
  curl/repos/staging-x86_64/
  curl/repos/staging-x86_64/PKGBUILD
    (from rev 343980, curl/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: curl/repos/staging-x86_64/PKGBUILD (from rev 343980, curl/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-01-13 19:39:24 UTC (rev 343981)
@@ -0,0 +1,58 @@
+# Maintainer: Dave Reisner <dreisner at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Lucien Immink <l.immink at student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=curl
+pkgver=7.63.0
+pkgrel=3
+pkgdesc="An URL retrieval utility and library"
+arch=('x86_64')
+url="https://curl.haxx.se"
+license=('MIT')
+depends=('ca-certificates' 'krb5' 'libssh2' 'openssl' 'zlib' 'libpsl' 'libnghttp2')
+provides=('libcurl.so')
+options=('strip' 'debug')
+source=("https://curl.haxx.se/download/$pkgname-$pkgver.tar.gz"{,.asc}
+         'curl-3399.patch::https://github.com/curl/curl/commit/6dc1780ea54129b3e6721fe9ee3f9d4f1d7abc1b.patch')
+sha512sums=('25ad69a1978de2178ac7a456e72152907203931ad895234c14781c27681ea2c5d6669794880c4ebae6e38b8014c6538bc88a6afec2c192210b6d491d60b8f691'
+            'SKIP'
+            '8a351ee445f79e54b46cc584fc0c341875d012f1db6e858de1b790177f12c622361eeccec1758d439ef1d839c9688899dd761b949b33311aa717709ba6040c05')
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  # See https://github.com/curl/curl/issues/3392
+  patch -p1 -i "$srcdir/curl-3399.patch"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  ./configure \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --disable-ldap \
+      --disable-ldaps \
+      --disable-manual \
+      --enable-ipv6 \
+      --enable-versioned-symbols \
+      --enable-threaded-resolver \
+      --with-gssapi \
+      --with-libssh2 \
+      --with-random=/dev/urandom \
+      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
+
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+  make DESTDIR="$pkgdir" install -C scripts
+
+  # license
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}