[arch-commits] Commit in python-numpy/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Mon Jan 14 07:39:37 UTC 2019
Date: Monday, January 14, 2019 @ 07:39:37
Author: felixonmars
Revision: 344058
archrelease: copy trunk to testing-x86_64
Added:
python-numpy/repos/testing-x86_64/
python-numpy/repos/testing-x86_64/PKGBUILD
(from rev 344057, python-numpy/trunk/PKGBUILD)
----------+
PKGBUILD | 77 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 77 insertions(+)
Copied: python-numpy/repos/testing-x86_64/PKGBUILD (from rev 344057, python-numpy/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2019-01-14 07:39:37 UTC (rev 344058)
@@ -0,0 +1,77 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+
+pkgbase=python-numpy
+pkgname=('python-numpy' 'python2-numpy')
+pkgver=1.16.0
+pkgrel=1
+pkgdesc="Scientific tools for Python"
+arch=('x86_64')
+license=('custom')
+url="http://www.numpy.org/"
+makedepends=('cblas' 'lapack' 'python' 'python2' 'python-setuptools' 'python2-setuptools'
+ 'gcc-fortran' 'python-nose' 'python2-nose' 'cython' 'cython2')
+checkdepends=('python-pytest' 'python2-pytest')
+options=('staticlibs')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/numpy/numpy/archive/v$pkgver.tar.gz")
+sha512sums=('fb1ef9c4e9d664b3c5db47dfd261dcaaaad7ee8b4eb48eb167812de893de88ca0b9a984a56a039958f03184dbc369bcd58e03f89447ef71cf61294bb1fd6eb7f')
+
+prepare() {
+ cp -a numpy-$pkgver{,-py2}
+ cd numpy-$pkgver-py2
+
+ sed -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/python2|" \
+ -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
+ -e "s|#![ ]*/bin/env python$|#!/usr/bin/env python2|" \
+ -i $(find . -name '*.py')
+}
+
+build() {
+ cd "$srcdir"/numpy-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/numpy-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ # TODO: Fix fortran tests here (it works fine after installation)
+
+ cd "$srcdir"/numpy-$pkgver
+ python setup.py install --root="$PWD/tmp_install" --optimize=1
+ cd "$PWD/tmp_install"
+ PATH="$PWD/usr/bin:$PATH" PYTHONPATH="$PWD/usr/lib/python3.7/site-packages:$PYTHONPATH" python -c 'import numpy; numpy.test()'
+
+ cd "$srcdir"/numpy-$pkgver-py2
+ python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+ cd "$PWD/tmp_install"
+ PATH="$PWD/usr/bin:$PATH" PYTHONPATH="$PWD/usr/lib/python2.7/site-packages:$PYTHONPATH" python2 -c 'import numpy; numpy.test()'
+}
+
+package_python-numpy() {
+ depends=('cblas' 'lapack' 'python')
+ optdepends=('python-nose: testsuite'
+ 'openblas: faster linear algebra')
+
+ cd numpy-$pkgver
+ python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
+
+ install -m755 -d "${pkgdir}/usr/share/licenses/python-numpy"
+ install -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/python-numpy/"
+}
+
+package_python2-numpy() {
+ depends=('cblas' 'lapack' 'python2')
+ optdepends=('python2-nose: testsuite'
+ 'openblas: faster linear algebra')
+
+ cd numpy-$pkgver-py2
+ python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+
+ install -m755 -d "${pkgdir}/usr/share/licenses/python2-numpy"
+ install -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/python2-numpy/"
+
+ mv "$pkgdir"/usr/bin/f2py{,2}
+}
More information about the arch-commits
mailing list