[arch-commits] Commit in gnuradio-osmosdr/repos (2 files)

[Felix Yan]

    Date: Tuesday, January 15, 2019 @ 07:56:24
  Author: felixonmars
Revision: 423178

archrelease: copy trunk to community-staging-x86_64

Added:
  gnuradio-osmosdr/repos/community-staging-x86_64/
  gnuradio-osmosdr/repos/community-staging-x86_64/PKGBUILD
    (from rev 423177, gnuradio-osmosdr/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: gnuradio-osmosdr/repos/community-staging-x86_64/PKGBUILD (from rev 423177, gnuradio-osmosdr/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-01-15 07:56:24 UTC (rev 423178)
@@ -0,0 +1,43 @@
+# Maintainer: Kyle Keen <keenerd at gmail.com?>
+# Contributor: Dominik Heidler <dheidler at gmail.com>
+pkgname=gnuradio-osmosdr
+_pkgname=gr-osmosdr
+pkgver=0.1.4
+pkgrel=29
+pkgdesc="Source block for Funcube Dongle, RTL-SDR, USRP, OsmoSDR, BladeRF, HackRF and AirSpy devices"
+url="http://sdr.osmocom.org/trac/"
+arch=('x86_64')
+license=('GPL')
+depends=('gnuradio' 'gnuradio-iqbal' 'rtl-sdr' 'gnuradio-fcdproplus' 'hackrf' 'bladerf' 'airspy')
+optdepends=('python2-opengl: osmocom_fft')
+makedepends=('git' 'cmake' 'boost' 'python2-cheetah' 'swig')
+conflicts=('gr-osmosdr-git')
+replaces=('gr-osmosdr')
+source=("git://git.osmocom.org/gr-osmosdr#tag=v$pkgver")
+md5sums=('SKIP')
+
+# add support for miri, osmo?
+
+prepare() {
+  cd "$srcdir/$_pkgname"
+  sed -i 's/python$/python2/' apps/osmocom_siggen_base.py
+}
+
+build() {
+  cd "$srcdir/$_pkgname"
+  mkdir build
+  cd build
+  cmake \
+    -Wno-dev \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DPYTHON_EXECUTABLE=$(which python2) \
+    -DPYTHON_INCLUDE_DIR=$(echo /usr/include/python2*) \
+    -DPYTHON_LIBRARY=$(echo /usr/lib/libpython2.*.so) \
+    -DCMAKE_INSTALL_PREFIX=/usr ../
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgname/build/"
+  make DESTDIR="${pkgdir}" install
+}