[arch-commits] Commit in adriconf/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Jan 15 08:49:01 UTC 2019


    Date: Tuesday, January 15, 2019 @ 08:49:00
  Author: felixonmars
Revision: 423210

archrelease: copy trunk to community-staging-x86_64

Added:
  adriconf/repos/community-staging-x86_64/
  adriconf/repos/community-staging-x86_64/PKGBUILD
    (from rev 423209, adriconf/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: adriconf/repos/community-staging-x86_64/PKGBUILD (from rev 423209, adriconf/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-01-15 08:49:00 UTC (rev 423210)
@@ -0,0 +1,49 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=adriconf
+pkgver=1.3
+pkgrel=6
+pkgdesc="GUI tool to configure Mesa drivers by setting options and writing them to the standard drirc file"
+arch=(x86_64)
+url="https://github.com/jlHertel/adriconf"
+license=(GPL3)
+depends=(boost-libs gtkmm3 libxml++ pciutils)
+makedepends=(boost cmake git gtest)
+_commit=93e4ac64999c3ef3f73aab593cca642ef1d9da6f  # tags/v1.3
+source=("git+https://github.com/jlHertel/adriconf#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  mkdir -p build
+  cd $pkgname
+
+  # Build with libxml++ 3.0
+  # https://github.com/jlHertel/adriconf/issues/47
+  sed -i 's/libxml++-2.6/libxml++-3.0/' CMakeLists.txt
+
+  # Fix AppStream metadata
+  # https://github.com/jlHertel/adriconf/pull/41
+  git cherry-pick -n f4bf2225bad563b15161e193bf7ccecbd0c6d578
+}
+
+build() {
+  cd build
+  cmake ../$pkgname \
+    -DCMAKE_INSTALL_PREFIX=/usr
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  cd ../$pkgname
+  install -Dm644 flatpak/br.com.jeanhertel.adriconf.appdata.xml "$pkgdir/usr/share/metainfo/br.com.jeanhertel.adriconf.appdata.xml"
+  install -Dm644 flatpak/br.com.jeanhertel.adriconf.desktop "$pkgdir/usr/share/applications/br.com.jeanhertel.adriconf.desktop"
+  install -Dm644 flatpak/br.com.jeanhertel.adriconf.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/br.com.jeanhertel.adriconf.png"
+}


More information about the arch-commits mailing list