[arch-commits] Commit in python-language-server/repos (2 files)

[Maxim Baz]

    Date: Wednesday, January 16, 2019 @ 19:13:18
  Author: maximbaz
Revision: 423699

archrelease: copy trunk to community-staging-any

Added:
  python-language-server/repos/community-staging-any/
  python-language-server/repos/community-staging-any/PKGBUILD
    (from rev 423698, python-language-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

Copied: python-language-server/repos/community-staging-any/PKGBUILD (from rev 423698, python-language-server/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-01-16 19:13:18 UTC (rev 423699)
@@ -0,0 +1,73 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Maintainer: Maxim Baz <$pkgbase at maximbaz dot com>
+# Contributor: fenuks
+
+pkgbase=python-language-server
+pkgname=(python-language-server python2-language-server)
+pkgver=0.21.5
+pkgrel=1
+pkgdesc="An implementation of the Language Server Protocol for Python"
+arch=("any")
+url="https://github.com/palantir/python-language-server"
+license=("MIT")
+makedepends=("python" "python-setuptools"
+             "python2" "python2-setuptools")
+checkdepends=("python-pytest" "python-pytest-runner" "python-pytest-cov"  "python-pyflakes"
+              "python-mock" "python-jedi" "python-future" "yapf" "python-mccabe" "python-pycodestyle"
+	          "autopep8" "python-rope" "python-pydocstyle" "python-jsonrpc-server"
+              "python2-pytest" "python2-pytest-runner" "python2-pytest-cov" "python2-pyflakes"
+	          "python2-autopep8" "python2-rope" "python2-mccabe" "python2-pydocstyle" "python2-jsonrpc-server"
+	          "python2-mock" "python2-jedi" "python2-future" "python2-futures" "python2-yapf" "python2-pycodestyle" "python2-autopep8")
+source=("$pkgname-$pkgver.tar.gz::https://github.com/palantir/${pkgname}/archive/${pkgver}.tar.gz")
+sha256sums=('118831f32c62cbb9da82d3dc888d519664fd68ad4b79fcad427602b2904970da')
+
+prepare() {
+  cp -r "$pkgname-$pkgver"{,-py2}
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    python setup.py build
+
+    cd "${srcdir}/${pkgname}-${pkgver}-py2"
+    python2 setup.py build
+}
+
+check() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    py.test
+
+    cd "${srcdir}/${pkgname}-${pkgver}-py2"
+    py.test2
+}
+
+package_python-language-server() {
+    depends=("python" "python-jsonrpc-server" "python-future" "python-jedi" "python-pluggy")
+    optdepends=(
+	"python-mccabe: for complexity checking"
+        "python-rope: for completions and renaming"
+	"python-pyflakes: for linter to detect various errors"
+	"python-pycodestyle: for style checking"
+	"autopep8: for code formatting"
+	"yapf: for code formatting (preferred over autopep8)"
+	"python-pydocstyle: for docstring style checking")
+    cd "${pkgbase}-${pkgver}"
+    python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-language-server() {
+    depends=("python2" "python2-jsonrpc-server" "python2-future" "python2-jedi" "python2-pluggy")
+    optdepends=(
+	"python2-mccabe: for complexity checking"
+        "python2-rope: for completions and renaming"
+	"python2-pyflakes: for linter to detect various errors"
+	"python2-pycodestyle: for style checking"
+	"python2-autopep8: for code formatting"
+	"python2-yapf: for code formatting (preferred over autopep8)"
+	"python2-pydocstyle: for docstring style checking")
+    cd "${pkgbase}-${pkgver}-py2"
+    python2 setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
+    mv "$pkgdir/usr/bin/pyls" "$pkgdir/usr/bin/pyls2"
+    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}