[arch-commits] Commit in python-js2py/repos (community-any community-any/PKGBUILD)

Felix Yan felixonmars at archlinux.org
Fri Jan 25 20:59:42 UTC 2019


    Date: Friday, January 25, 2019 @ 20:59:42
  Author: felixonmars
Revision: 427918

archrelease: copy trunk to community-any

Added:
  python-js2py/repos/community-any/
  python-js2py/repos/community-any/PKGBUILD
    (from rev 427917, python-js2py/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-js2py/repos/community-any/PKGBUILD (from rev 427917, python-js2py/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2019-01-25 20:59:42 UTC (rev 427918)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-js2py
+pkgname=(python-js2py python2-js2py)
+pkgver=0.60
+_commit=c328582f399a5afb604d616b4f1961217179f220
+pkgrel=1
+pkgdesc="JavaScript to Python Translator & JavaScript interpreter written in 100% pure Python"
+url="https://github.com/PiotrDabkowski/Js2Py"
+license=('MIT')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-tzlocal' 'python2-tzlocal'
+             'python-six' 'python2-six' 'python-pyjsparser' 'python2-pyjsparser')
+checkdepends=('npm' 'python-numpy' 'python2-numpy')
+source=("$pkgbase-$_commit.tar.gz::https://github.com/PiotrDabkowski/Js2Py/archive/$_commit.tar.gz")
+sha512sums=('25fa4f5ec6819a9cff3604c80d24b26f1e220fc5a63b9a822e6b59c5ebb7c05b85dd37a165e047e3c3e6851dd0af8a38f2b331c8473247438dff9302e832f9a5')
+
+prepare() {
+  mv Js2Py-{$_commit,$pkgver}
+}
+
+build() {
+  cd Js2Py-$pkgver
+  python setup.py build
+  python2 setup.py build
+}
+
+check() {
+  cd Js2Py-$pkgver
+  python simple_test.py
+  python2 simple_test.py || warning "https://github.com/PiotrDabkowski/Js2Py/issues/149"
+}
+
+package_python-js2py() {
+  depends=('python-tzlocal' 'python-six' 'python-pyjsparser')
+
+  cd Js2Py-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+}
+
+package_python2-js2py() {
+  depends=('python2-tzlocal' 'python2-six' 'python2-pyjsparser')
+
+  cd Js2Py-$pkgver
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+}


More information about the arch-commits mailing list