[arch-commits] Commit in hoogle/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Jan 29 07:14:12 UTC 2019


    Date: Tuesday, January 29, 2019 @ 07:14:11
  Author: felixonmars
Revision: 428370

archrelease: copy trunk to community-staging-x86_64

Added:
  hoogle/repos/community-staging-x86_64/
  hoogle/repos/community-staging-x86_64/PKGBUILD
    (from rev 428369, hoogle/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: hoogle/repos/community-staging-x86_64/PKGBUILD (from rev 428369, hoogle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-01-29 07:14:11 UTC (rev 428370)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hoogle
+pkgver=5.0.17.3
+pkgrel=162
+pkgdesc="Haskell API Search"
+url="http://www.haskell.org/hoogle/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-aeson' 'haskell-cmdargs' 'haskell-conduit'
+         'haskell-conduit-extra' 'haskell-connection' 'haskell-extra' 'haskell-src-exts'
+         'haskell-http-conduit' 'haskell-http-types' 'haskell-js-flot' 'haskell-js-jquery'
+         'haskell-mmap' 'haskell-network' 'haskell-network-uri' 'haskell-old-locale'
+         'haskell-process-extras' 'haskell-resourcet' 'haskell-storable-tuple' 'haskell-tar'
+         'haskell-uniplate' 'haskell-utf8-string' 'haskell-vector' 'haskell-wai'
+         'haskell-wai-logger' 'haskell-warp' 'haskell-warp-tls' 'haskell-zlib')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('b8113e9dc6f44fbf684edfe6134eb44d55b1ef43afc3cb2051920daaec3e108df6209cfe822a8eeff884360c9b9415f2ab8273e7681e6bbcc1b9c77490370195')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fnetwork-uri
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list