[arch-commits] Commit in xmonad-contrib/repos (2 files)

[Felix Yan]

    Date: Monday, July 1, 2019 @ 17:10:25
  Author: felixonmars
Revision: 487164

archrelease: copy trunk to community-staging-x86_64

Added:
  xmonad-contrib/repos/community-staging-x86_64/
  xmonad-contrib/repos/community-staging-x86_64/PKGBUILD
    (from rev 487163, xmonad-contrib/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: xmonad-contrib/repos/community-staging-x86_64/PKGBUILD (from rev 487163, xmonad-contrib/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-07-01 17:10:25 UTC (rev 487164)
@@ -0,0 +1,42 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Vesa Kaihlavirta <vegai at iki.fi>
+# Contributor: orbisvicis <gmail.com>
+
+pkgname=xmonad-contrib
+pkgver=0.15
+pkgrel=13
+pkgdesc='Add-ons for xmonad'
+url='http://xmonad.org/'
+arch=('x86_64')
+license=('BSD')
+depends=('ghc-libs' 'xmonad' 'sh' 'haskell-x11' 'haskell-x11-xft' 'haskell-utf8-string' 'haskell-random'
+         'haskell-old-time')
+makedepends=('ghc')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/xmonad/xmonad-contrib/archive/v${pkgver}.tar.gz)
+sha512sums=('3690ede8744f688e67417aff63ab840eb7fb3c20ea7c6b13a8ccc5233ad34dd131ce5758b25af2bcf6a791ea7f4767f1147d86f291a4e251434ba8db03631dd7')
+
+prepare() {
+  sed -i -e '/semigroups/d' -e 's/utf8-string,/utf8-string/' ${pkgname}-${pkgver}/${pkgname}.cabal
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  runhaskell Setup.lhs configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+             --prefix=/usr -fuse_xft --libsubdir=\$compiler/site-local/\$pkgid \
+             --docdir=/usr/share/doc/${pkgname}
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  install -Dm 744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+  install -Dm 744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+  runhaskell Setup.lhs copy --destdir="${pkgdir}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}