[arch-commits] Commit in aria2/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, July 6, 2019 @ 07:14:00
  Author: foutrelis
Revision: 487498

archrelease: copy trunk to community-staging-x86_64

Added:
  aria2/repos/community-staging-x86_64/
  aria2/repos/community-staging-x86_64/PKGBUILD
    (from rev 487497, aria2/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: aria2/repos/community-staging-x86_64/PKGBUILD (from rev 487497, aria2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-07-06 07:14:00 UTC (rev 487498)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=aria2
+pkgver=1.34.0
+pkgrel=3
+pkgdesc='Download utility that supports HTTP(S), FTP, BitTorrent, and Metalink'
+arch=('x86_64')
+url='http://aria2.sourceforge.net/'
+license=('GPL')
+depends=('gnutls' 'libxml2' 'sqlite' 'c-ares' 'ca-certificates' 'libssh2')
+checkdepends=('cppunit')
+source=("https://github.com/tatsuhiro-t/aria2/releases/download/release-$pkgver/aria2-$pkgver.tar.xz")
+sha512sums=('80bc43e242c06acc95030021cb347b4ec230729f3d7e512ca1932941b34ef95c312a34007a226869e5d720839a400e66cdb072ccab5d42228d8cf3d828723dcc')
+
+build() {
+  cd $pkgname-$pkgver
+
+  ./configure \
+    --prefix=/usr \
+    --enable-libaria2 \
+    --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
+
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make check
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+
+  # add bash completion
+  install -d "$pkgdir"/usr/share/bash-completion/completions
+  install -m644 "$pkgdir"/usr/share/doc/aria2/bash_completion/aria2c \
+    "$pkgdir"/usr/share/bash-completion/completions
+  rm -rf "$pkgdir"/usr/share/doc/aria2/bash_completion
+}