[arch-commits] Commit in (7 files)

Felix Yan felixonmars at archlinux.org
Sun Jul 7 01:54:06 UTC 2019


    Date: Sunday, July 7, 2019 @ 01:54:06
  Author: felixonmars
Revision: 487554

addpkg: motion 4.2.2-1

Added:
  motion/
  motion/repos/
  motion/trunk/
  motion/trunk/PKGBUILD
  motion/trunk/motion.service
  motion/trunk/motion.sysusers
  motion/trunk/motion.tmpfiles

-----------------+
 PKGBUILD        |   44 ++++++++++++++++++++++++++++++++++++++++++++
 motion.service  |   12 ++++++++++++
 motion.sysusers |    2 ++
 motion.tmpfiles |    1 +
 4 files changed, 59 insertions(+)

Added: motion/trunk/PKGBUILD
===================================================================
--- motion/trunk/PKGBUILD	                        (rev 0)
+++ motion/trunk/PKGBUILD	2019-07-07 01:54:06 UTC (rev 487554)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: mrxx <mrxx at cyberhome dot at>
+# Contributor: Evgeny Kurnevsky <kurnevsky at gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+
+pkgname=motion
+pkgver=4.2.2
+pkgrel=1
+pkgdesc="Monitor and record video signals from many types of cameras"
+arch=('x86_64')
+license=('GPL')
+url="https://motion-project.github.io"
+depends=('sqlite' 'ffmpeg' 'libmicrohttpd' 'libwebp')
+optdepends=('gettext: native language support')
+backup=('etc/motion/motion.conf')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/Motion-Project/motion/archive/release-$pkgver.tar.gz"
+        'motion.service'
+        'motion.sysusers'
+        'motion.tmpfiles')
+sha256sums=('c8d40976b41da8eb9f9f7128599403a312fc26b7226bf3787d75f78cb5a6cc6e'
+            'a78dba35414f4d7147cc2c622eecdb3df249978023cbea5c6bc420c34ca387e7'
+            '353fe3c2ee0afb7dafe1c6b7d1ac5655449dab836ab387cf335b4bd1dd37bf27'
+            'b34eaf6b085a25ef310102f892d0909247f1acb9d6a75cc9faca85e1ef076a1c')
+
+build() {
+  cd $pkgname-release-$pkgver
+  autoreconf
+  ./configure --prefix=/usr \
+    --without-pgsql \
+    --without-mysql \
+    --sysconfdir=/etc \
+    --with-ffmpeg \
+    --with-webp
+  make
+}
+
+package(){
+  cd $pkgname-release-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm644 motion-dist.conf "$pkgdir"/etc/motion/motion.conf
+  install -Dm644 "$srcdir"/motion.service "$pkgdir"/usr/lib/systemd/system/motion.service
+  install -Dm644 "$srcdir"/motion.sysusers "$pkgdir"/usr/lib/sysusers.d/motion.conf
+  install -Dm644 "$srcdir"/motion.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/motion.conf
+}

Added: motion/trunk/motion.service
===================================================================
--- motion/trunk/motion.service	                        (rev 0)
+++ motion/trunk/motion.service	2019-07-07 01:54:06 UTC (rev 487554)
@@ -0,0 +1,12 @@
+[Unit]
+Description=Motion daemon
+After=local-fs.target network.target
+
+[Service]
+User=motion
+ExecStart=/usr/bin/motion -n
+Type=simple
+StandardError=null
+
+[Install]
+WantedBy=multi-user.target

Added: motion/trunk/motion.sysusers
===================================================================
--- motion/trunk/motion.sysusers	                        (rev 0)
+++ motion/trunk/motion.sysusers	2019-07-07 01:54:06 UTC (rev 487554)
@@ -0,0 +1,2 @@
+u motion - - /var/lib/motion
+m motion video

Added: motion/trunk/motion.tmpfiles
===================================================================
--- motion/trunk/motion.tmpfiles	                        (rev 0)
+++ motion/trunk/motion.tmpfiles	2019-07-07 01:54:06 UTC (rev 487554)
@@ -0,0 +1 @@
+d /var/lib/motion 0700 motion motion - -


More information about the arch-commits mailing list