[arch-commits] Commit in (4 files)

[David Runge]

    Date: Sunday, July 7, 2019 @ 14:55:46
  Author: dvzrv
Revision: 487630

Adding php-redis as optdepends for nextcloud.

Added:
  php-redis/
  php-redis/repos/
  php-redis/trunk/
  php-redis/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: php-redis/trunk/PKGBUILD
===================================================================
--- php-redis/trunk/PKGBUILD	                        (rev 0)
+++ php-redis/trunk/PKGBUILD	2019-07-07 14:55:46 UTC (rev 487630)
@@ -0,0 +1,44 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+
+pkgname=php-redis
+_name=redis
+_upstream=phpredis
+pkgver=5.0.0
+pkgrel=1
+pkgdesc="An API for communicating with the Redis key-value store"
+arch=('x86_64')
+url="https://github.com/phpredis/phpredis/"
+license=('PHP')
+depends=('php' 'liblzf')
+checkdepends=('redis')
+optdepends=('redis: use a local redis instance')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/${_upstream}/${_upstream}/archive/${pkgver}.tar.gz")
+sha512sums=('3826cdb48c2747d36ea3ce44eb046ffb3e56e525181276dfa2b88d5484064aa444ae8254954a93260e8d21a095d690eea908d9394721dc5d169e05e92256b575')
+
+prepare() {
+  mv -v "${_upstream}-${pkgver}" "$pkgname-$pkgver"
+  cd "$pkgname-$pkgver"
+  echo ";extension=${_name}" > "${_name}.ini"
+  phpize
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  ./configure --prefix=/usr \
+              --enable-redis-lzf \
+              --with-liblzf=/usr/lib/
+  make
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  make -k test
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make INSTALL_ROOT="$pkgdir/" install
+  install -vDm 644 "${_name}.ini" -t "${pkgdir}/etc/php/conf.d/"
+  install -vDm 644 {{README,arrays,cluster}.markdown,CREDITS} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/"
+}