[arch-commits] Commit in mutter/repos (3 files)

[Jan Steffens]

    Date: Friday, July 12, 2019 @ 17:28:16
  Author: heftig
Revision: 357787

archrelease: copy trunk to testing-x86_64

Added:
  mutter/repos/testing-x86_64/
  mutter/repos/testing-x86_64/PKGBUILD
    (from rev 357786, mutter/trunk/PKGBUILD)
  mutter/repos/testing-x86_64/mutter.install
    (from rev 357786, mutter/trunk/mutter.install)

----------------+
 PKGBUILD       |   56 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 mutter.install |    7 ++++++
 2 files changed, 63 insertions(+)

Copied: mutter/repos/testing-x86_64/PKGBUILD (from rev 357786, mutter/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-07-12 17:28:16 UTC (rev 357787)
@@ -0,0 +1,56 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter
+pkgver=3.32.2+40+gccab0f470
+pkgrel=1
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas libcanberra
+         startup-notification zenity libsm gnome-desktop upower libxkbcommon-x11
+         gnome-settings-daemon libgudev libinput pipewire xorg-server-xwayland)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server)
+checkdepends=(xorg-server-xvfb)
+groups=(gnome)
+install=mutter.install
+_commit=ccab0f470dcc556073754c8adf9413819d22cc14  # gnome-3-32
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # rt-scheduler experimental feature
+  git cherry-pick -n dae2c1d420ed272710ac55b7a00f6787e5c0e762
+
+  # required to build gala
+  git cherry-pick -n bd7704f9e17e9554ad663386ef4fce1e16a56f08
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D installed_tests=false
+  ninja -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  dbus-run-session xvfb-run -s '+iglx -noreset' meson test -C build --print-errorlogs
+)
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: mutter/repos/testing-x86_64/mutter.install (from rev 357786, mutter/trunk/mutter.install)
===================================================================
--- testing-x86_64/mutter.install	                        (rev 0)
+++ testing-x86_64/mutter.install	2019-07-12 17:28:16 UTC (rev 357787)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/mutter
+}
+
+post_upgrade() {
+  post_install
+}