[arch-commits] Commit in spdlog/repos (2 files)

[Brett Cornwall]

    Date: Monday, July 15, 2019 @ 13:57:04
  Author: ainola
Revision: 489872

archrelease: copy trunk to community-staging-any

Added:
  spdlog/repos/community-staging-any/
  spdlog/repos/community-staging-any/PKGBUILD
    (from rev 489871, spdlog/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: spdlog/repos/community-staging-any/PKGBUILD (from rev 489871, spdlog/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-07-15 13:57:04 UTC (rev 489872)
@@ -0,0 +1,45 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+# Contributor: Luca Weiss
+# Contributor: Michael Yang
+
+pkgname=spdlog
+pkgver=1.3.1
+pkgrel=1
+pkgdesc='Very fast, header-only/compiled, C++ logging library'
+arch=('any')
+url='https://github.com/gabime/spdlog'
+license=('MIT')
+makedepends=('cmake' 'fmt')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/gabime/spdlog/archive/v$pkgver.tar.gz")
+sha256sums=('160845266e94db1d4922ef755637f6901266731c4cb3b30b45bf41efa0e6ab70')
+
+prepare() {
+    mkdir -p build
+}
+
+build() {
+    cd build
+    cmake ../"$pkgname-$pkgver" \
+        -DSPDLOG_BUILD_BENCH=OFF \
+        -DSPDLOG_BUILD_EXAMPLES=OFF \
+        -DSPDLOG_FMT_EXTERNAL=ON \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib
+    make
+}
+
+check() {
+    cd build
+    make test
+}
+
+package() {
+    cd build
+    make DESTDIR="$pkgdir" install
+    install -Dm644 ../"$pkgname-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
+
+    # Don't duplicate code from another project...
+    # https://github.com/gabime/spdlog/issues/1146
+    rm -r "$pkgdir/usr/include/spdlog/fmt/"
+}