[arch-commits] Commit in fio/repos (2 files)

Anatol Pomozov anatolik at archlinux.org
Mon Jul 15 20:15:06 UTC 2019


    Date: Monday, July 15, 2019 @ 20:15:05
  Author: anatolik
Revision: 489883

archrelease: copy trunk to community-testing-x86_64

Added:
  fio/repos/community-testing-x86_64/
  fio/repos/community-testing-x86_64/PKGBUILD
    (from rev 489882, fio/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: fio/repos/community-testing-x86_64/PKGBUILD (from rev 489882, fio/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-07-15 20:15:05 UTC (rev 489883)
@@ -0,0 +1,46 @@
+# Maintainer: Anatol Pomozov <anatol dot pomozov at gmail>
+# Contributor: Mariusz Libera <mariusz.libera at gmail.com>
+# Contributor: John Williams <jwilliams4200 liamg reverse&remove moc>
+
+pkgname=fio
+pkgver=3.15
+pkgrel=1
+pkgdesc='Scriptable I/O tool for storage benchmarks and drive testing'
+arch=(x86_64)
+url='https://github.com/axboe/fio'
+license=(GPL2)
+# TODO: enable rdma, need to move the libraries from AUR
+depends=(bash libaio python2 numactl glusterfs)
+makedepends=(gtk2)
+optdepends=(
+  'gtk2: for gfio - fio GUI frontend' 
+  'gnuplot: generating plots using fio_generate_plots'
+)
+source=(https://github.com/axboe/fio/archive/fio-$pkgver.zip)
+sha256sums=('1b248dd4597a0915225cd606705bdd917fb15b210511e879c050771cceba3598')
+
+prepare() {
+  cd fio-fio-$pkgver
+  sed -e 's|#!/usr/bin/env python|#!/usr/bin/env python2|' -i tools/plot/fio2gnuplot
+}
+
+build() {
+  cd fio-fio-$pkgver
+  ./configure --disable-native --enable-gfio --extra-cflags="$CFLAGS"
+  make
+}
+
+package() {
+  cd fio-fio-$pkgver
+  make DESTDIR="$pkgdir" prefix=/usr mandir=/usr/share/man install
+
+  # documentation
+  install -dm755 "$pkgdir/usr/share/doc/$pkgname"
+  install -m644 HOWTO README REPORTING-BUGS SERVER-TODO "$pkgdir/usr/share/doc/$pkgname"
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+  install -Dm644 MORAL-LICENSE "$pkgdir/usr/share/licenses/$pkgname/MORAL-LICENSE"
+
+  # examples
+  install -dm755 "$pkgdir/usr/share/doc/$pkgname/examples"
+  install -m644 examples/* "$pkgdir/usr/share/doc/$pkgname/examples"
+}



More information about the arch-commits mailing list