[arch-commits] Commit in (9 files)
Maxime Gauduin
alucryd at archlinux.org
Tue Jul 16 13:13:06 UTC 2019
Date: Tuesday, July 16, 2019 @ 13:13:06
Author: alucryd
Revision: 490034
add deps for home-assistant
Added:
python-astral/
python-astral/trunk/
python-astral/trunk/PKGBUILD
python-slugify/
python-slugify/trunk/
python-slugify/trunk/PKGBUILD
python-voluptuous-serialize/
python-voluptuous-serialize/trunk/
python-voluptuous-serialize/trunk/PKGBUILD
--------------------------------------------+
python-astral/trunk/PKGBUILD | 35 +++++++++++++++++++++++++
python-slugify/trunk/PKGBUILD | 34 ++++++++++++++++++++++++
python-voluptuous-serialize/trunk/PKGBUILD | 37 +++++++++++++++++++++++++++
3 files changed, 106 insertions(+)
Added: python-astral/trunk/PKGBUILD
===================================================================
--- python-astral/trunk/PKGBUILD (rev 0)
+++ python-astral/trunk/PKGBUILD 2019-07-16 13:13:06 UTC (rev 490034)
@@ -0,0 +1,35 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ekin Dursun <ekindursun at gmail.com>
+# Contributor: Gregoire Seux <grego_aur at familleseux.net>
+
+pkgname=python-astral
+pkgver=1.10.1
+pkgrel=1
+pkgdesc='Python calculations for the position of the sun and moon'
+arch=(any)
+url=https://github.com/sffjunkie/astral
+license=(APACHE)
+depends=(
+ python-pytz
+ python-requests
+)
+makedepends=(
+ git
+ python-setuptools
+)
+source=(git+https://github.com/sffjunkie/astral.git#tag=${pkgver})
+sha256sums=('SKIP')
+
+build() {
+ cd astral
+
+ python setup.py build
+}
+
+package() {
+ cd astral
+
+ python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+}
+
+# vim: ts=2 sw=2 et:
Added: python-slugify/trunk/PKGBUILD
===================================================================
--- python-slugify/trunk/PKGBUILD (rev 0)
+++ python-slugify/trunk/PKGBUILD 2019-07-16 13:13:06 UTC (rev 490034)
@@ -0,0 +1,34 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Thomas Jost <schnouki at schnouki.net>
+# Contributor: Andrey Mikhaylenko <neithere at gmail.com>
+
+pkgname=python-slugify
+pkgver=3.0.2
+pkgrel=1
+pkgdesc='A Python slugify application that handles unicode'
+arch=(any)
+url=https://github.com/un33k/python-slugify
+license=(MIT)
+depends=(python-text-unidecode)
+makedepends=(
+ git
+ python-setuptools
+)
+optdepends=('python-unidecode: Unidecode support')
+source=(git+https://github.com/un33k/python-slugify.git#tag=${pkgver})
+sha256sums=(SKIP)
+
+build() {
+ cd python-slugify
+
+ python setup.py build
+}
+
+package() {
+ cd python-slugify
+
+ python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+ install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/python-slugify/
+}
+
+# vim: ts=2 sw=2 et:
Added: python-voluptuous-serialize/trunk/PKGBUILD
===================================================================
--- python-voluptuous-serialize/trunk/PKGBUILD (rev 0)
+++ python-voluptuous-serialize/trunk/PKGBUILD 2019-07-16 13:13:06 UTC (rev 490034)
@@ -0,0 +1,37 @@
+# Maintainer: Jameson Pugh <imntreal at gmail.com>
+
+pkgname=python-voluptuous-serialize
+pkgver=2.1.0
+pkgrel=1
+pkgdesc='Convert voluptuous schemas to JSON'
+arch=(any)
+url=https://github.com/balloob/voluptuous-serialize
+license=(APACHE)
+depends=(python-voluptuous)
+makedepends=(
+ git
+ python-setuptools
+)
+checkdepends=(python-pytest)
+source=(git+https://github.com/balloob/voluptuous-serialize.git#tag=${pkgver})
+sha256sums=(SKIP)
+
+build() {
+ cd voluptuous-serialize
+
+ python setup.py build
+}
+
+check() {
+ cd voluptuous-serialize
+
+ python setup.py test
+}
+
+package() {
+ cd voluptuous-serialize
+
+ python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list