[arch-commits] Commit in haskell-bytestring-strict-builder/repos (2 files)

Felix Yan felixonmars at archlinux.org
Wed Jul 17 21:17:42 UTC 2019


    Date: Wednesday, July 17, 2019 @ 21:17:41
  Author: felixonmars
Revision: 490736

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-bytestring-strict-builder/repos/community-staging-x86_64/
  haskell-bytestring-strict-builder/repos/community-staging-x86_64/PKGBUILD
    (from rev 490735, haskell-bytestring-strict-builder/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-bytestring-strict-builder/repos/community-staging-x86_64/PKGBUILD (from rev 490735, haskell-bytestring-strict-builder/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-07-17 21:17:41 UTC (rev 490736)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=bytestring-strict-builder
+pkgname=haskell-bytestring-strict-builder
+pkgver=0.4.5.3
+pkgrel=6
+pkgdesc="An efficient strict bytestring builder"
+url="https://github.com/nikita-volkov/bytestring-strict-builder"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-prelude')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-quickcheck'
+             'haskell-tasty-hunit' 'haskell-quickcheck-instances' 'haskell-rerebase')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('3527960d2c6db8acfb9273130d169558f769826c9f7c68dfd04c22d1172700dd42eef6c81dae8e8ee1ba93ca471ef7a3572da4d155eeaa9f44b065412537fda8')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -e '/semigroups/d' -i $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list