[arch-commits] Commit in kate/repos (kde-unstable-x86_64 kde-unstable-x86_64/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Fri Jul 19 19:38:07 UTC 2019


    Date: Friday, July 19, 2019 @ 19:38:06
  Author: arojas
Revision: 358232

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  kate/repos/kde-unstable-x86_64/
  kate/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 358231, kate/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: kate/repos/kde-unstable-x86_64/PKGBUILD (from rev 358231, kate/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2019-07-19 19:38:06 UTC (rev 358232)
@@ -0,0 +1,60 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=kate
+pkgname=(kwrite kate)
+pkgver=19.07.80
+pkgrel=1
+arch=(x86_64)
+license=(GPL LGPL FDL)
+makedepends=(extra-cmake-modules kdoctools plasma-framework knewstuff kitemmodels ktexteditor threadweaver kactivities)
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgbase-$pkgver.tar.xz"{,.sig})
+sha256sums=('d54918a6eaf097f590c245a31d3932ed0e4f1a902d3ed96d3c709e09439ffb58'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package_kwrite() {
+  pkgdesc="Text Editor"
+  groups=(kde-applications kdebase)
+  url="https://www.kde.org/applications/utilities/kwrite/"
+  depends=(ktexteditor kactivities hicolor-icon-theme)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  find "$pkgdir" -type f -name '*kate*' -exec rm {} \;
+  rm -r "$pkgdir"/usr/lib/qt/plugins/ktexteditor \
+        "$pkgdir"/usr/share/doc/HTML/*/{kate,katepart} \
+        "$pkgdir"/usr/share/katexmltools \
+        "$pkgdir"/usr/share/locale/*/LC_MESSAGES/{kterustcompletion,tabswitcherplugin,ktexteditorpreviewplugin,lspclient}.mo \
+        "$pkgdir"/usr/share/plasma/plasmoids
+}
+
+package_kate() {
+  pkgdesc="Advanced Text Editor"
+  groups=(kde-applications kdebase)
+  url="https://www.kde.org/applications/utilities/kate/"
+  depends=(knewstuff ktexteditor threadweaver kactivities hicolor-icon-theme)
+  optdepends=('konsole: open a terminal in Kate')
+
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  find "$pkgdir" -type f -name '*kwrite*' -exec rm {} \;
+  rm -r "$pkgdir"/usr/share/doc/HTML/*/kwrite
+}


More information about the arch-commits mailing list