[arch-commits] Commit in kdenlive/repos (2 files)

Antonio Rojas arojas at archlinux.org
Fri Jul 19 19:53:09 UTC 2019


    Date: Friday, July 19, 2019 @ 19:53:07
  Author: arojas
Revision: 358320

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  kdenlive/repos/kde-unstable-x86_64/
  kdenlive/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 358319, kdenlive/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: kdenlive/repos/kde-unstable-x86_64/PKGBUILD (from rev 358319, kdenlive/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2019-07-19 19:53:07 UTC (rev 358320)
@@ -0,0 +1,47 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Zuf <kontakt.zuf at gmail.com>
+# Contributor: Darwin Bautista <djclue917 at gmail.com>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+
+pkgname=kdenlive
+pkgver=19.07.80
+pkgrel=1
+pkgdesc="A non-linear video editor for Linux using the MLT video framework"
+arch=(x86_64)
+url="https://www.kdenlive.org/"
+license=(GPL)
+groups=(kde-applications kdemultimedia)
+depends=(knewstuff knotifyconfig kfilemetadata purpose mlt rttr breeze-icons frei0r-plugins)
+makedepends=(extra-cmake-modules kdoctools v4l-utils)
+optdepends=('ffmpeg: for FFmpeg plugin'
+            'cdrtools: for creation of DVD ISO images'
+            'dvdauthor: for creation of DVD'
+            'dvgrab: for firewire capture'
+            'recordmydesktop: for screen capture'
+            'xine-ui: for DVD preview'
+            'vlc: for DVD preview'
+            'plasma-desktop: theme configuration')
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('82c60b45586f91c8b923ce06ac323a6183471d5c26b6f540fd1fd38d7d2ba1fd'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}



More information about the arch-commits mailing list