[arch-commits] Commit in python-moto/repos/community-any (PKGBUILD PKGBUILD)

Chih-Hsuan Yen yan12125 at archlinux.org
Sat Jul 20 08:48:02 UTC 2019


    Date: Saturday, July 20, 2019 @ 08:48:01
  Author: yan12125
Revision: 492259

archrelease: copy trunk to community-any

Added:
  python-moto/repos/community-any/PKGBUILD
    (from rev 492258, python-moto/trunk/PKGBUILD)
Deleted:
  python-moto/repos/community-any/PKGBUILD

----------+
 PKGBUILD |  111 ++++++++++++++++++++++++++++++++-----------------------------
 1 file changed, 59 insertions(+), 52 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-07-20 08:47:31 UTC (rev 492258)
+++ PKGBUILD	2019-07-20 08:48:01 UTC (rev 492259)
@@ -1,52 +0,0 @@
-# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
-# Contributor: Guillaume Horel <guillaume.horel at gmail.com>
-
-pkgname=python-moto
-_pkgname=moto
-pkgver=1.3.10
-pkgrel=1
-pkgdesc='Moto is a library to mock out the boto library.'
-arch=(any)
-url='https://github.com/spulec/moto'
-license=(Apache)
-depends=(python-aws-xray-sdk python-boto python-boto3
-         python-cryptography python-dateutil python-docker python-jinja
-         python-jsondiff python-jose python-mock python-pyaml
-         python-pytz python-requests python-responses python-xmltodict
-         python-werkzeug python-cfn-lint python-setuptools python-sshpubkeys)
-checkdepends=(python-flask python-freezegun python-nose python-sure tk)
-optdepends=(
-  'python-flask: for moto_server'
-)
-source=("https://github.com/spulec/moto/archive/$pkgver/$pkgname-$pkgver.tar.gz"
-        moto-fix-setup.patch::https://github.com/yan12125/moto/commit/92bf8eff12b49def8e9689c57d26184c548546d0.patch)
-sha256sums=('3ecb76df66c47a59dd9cc7218f08265c04f2b963561b9d50a246221a63999d23'
-            '913485b0605c1b9cbb445b1862eb91ee6130430d5b735836f8e1b093565924d8')
-
-prepare() {
-  cd $_pkgname-$pkgver
-
-  patch -Np1 -i ../moto-fix-setup.patch
-
-  # Remove upper bounds of dependencies
-  sed --in-place=.orig -r 's#,?<[0-9.]+,?##;s#==([0-9.]+)#>=\1#' setup.py
-  diff -u setup.py{.orig,} || true
-}
-
-build() {
-  cd $_pkgname-$pkgver
-
-  python setup.py build
-}
-
-check() {
-  cd $_pkgname-$pkgver
-
-  TZ=UTC nosetests -sv ./tests/ --exclude='test_iot.*' --exclude='test_lambda.*'
-}
-
-package() {
-  cd $_pkgname-$pkgver
-
-  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
-}

Copied: python-moto/repos/community-any/PKGBUILD (from rev 492258, python-moto/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-07-20 08:48:01 UTC (rev 492259)
@@ -0,0 +1,59 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: Guillaume Horel <guillaume.horel at gmail.com>
+
+pkgname=python-moto
+_pkgname=moto
+pkgver=1.3.13
+pkgrel=1
+pkgdesc='Moto is a library to mock out the boto library.'
+arch=(any)
+url='https://github.com/spulec/moto'
+license=(Apache)
+depends=(python-aws-xray-sdk python-boto python-boto3
+         python-cryptography python-dateutil python-docker python-jinja
+         python-jsondiff python-jose python-mock python-pyaml
+         python-pytz python-requests python-responses python-xmltodict
+         python-werkzeug python-cfn-lint python-setuptools python-sshpubkeys)
+checkdepends=(python-flask python-freezegun python-nose python-sure tk)
+optdepends=(
+  'python-flask: for moto_server'
+)
+source=("https://files.pythonhosted.org/packages/source/m/moto/moto-$pkgver.tar.gz"
+        moto-fix-setup.patch::https://github.com/yan12125/moto/commit/92bf8eff12b49def8e9689c57d26184c548546d0.patch)
+sha256sums=('95d48d8ebaad47fb5bb4233854cf1cf8523ec5307d50eb1e4017ce10f1960b66'
+            '913485b0605c1b9cbb445b1862eb91ee6130430d5b735836f8e1b093565924d8')
+
+prepare() {
+  cd $_pkgname-$pkgver
+
+  patch -Np1 -i ../moto-fix-setup.patch
+
+  # Remove upper bounds of dependencies
+  sed --in-place=.orig -r 's#,?<[0-9.]+,?##;s#==([0-9.]+)#>=\1#' setup.py
+  diff -u setup.py{.orig,} || true
+}
+
+build() {
+  cd $_pkgname-$pkgver
+
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  # boto 2.x is broken with proxies https://github.com/boto/boto/issues/2869
+  # XXX: is there a way to skip boto 2.x tests only?
+  if [ -n "$http_proxy" -o -n "$https_proxy" ] ; then
+    warning "Skipping tests as some tests do not work with proxies."
+    return
+  fi
+
+  TZ=UTC nosetests -sv ./tests/ --exclude='test_iot.*' --exclude='test_lambda.*'
+}
+
+package() {
+  cd $_pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}


More information about the arch-commits mailing list