[arch-commits] Commit in fasm/repos (community-x86_64 community-x86_64/PKGBUILD)

[Levente Polyak]

    Date: Thursday, July 25, 2019 @ 00:33:34
  Author: anthraxx
Revision: 492748

archrelease: copy trunk to community-x86_64

Added:
  fasm/repos/community-x86_64/
  fasm/repos/community-x86_64/PKGBUILD
    (from rev 492747, fasm/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: fasm/repos/community-x86_64/PKGBUILD (from rev 492747, fasm/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2019-07-25 00:33:34 UTC (rev 492748)
@@ -0,0 +1,58 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Chris Andrews <christophersimonandrews [at] gmail [dot] com>
+# Contributor: FadeMind <fademind at gmail.com>
+# Contributor: Serge Victor <arch at random.re>
+# Contributor: Krzysztof Wloch <wloszekk [at] gmail [dot] com>
+# Contributor: Luke McCarthy <luke at iogopro.co.uk>
+
+pkgname=fasm
+pkgver=1.73.13
+pkgrel=1
+pkgdesc='Fast and efficient self-assembling x86 assembler for DOS, Windows and Linux operating systems'
+url='https://flatassembler.net/'
+arch=('x86_64')
+license=('custom')
+depends_x86_64=('lib32-glibc' 'lib32-gcc-libs')
+source=(https://flatassembler.net/${pkgname}-${pkgver}.tgz)
+sha256sums=('c85caaf6cd8b7fd71f64d3408648cc121ce79c975b32e73d418ecbaacf8189bc')
+sha512sums=('09385bd7ac95f0a5ab81f14bd28a9bf8e0575031190df793a60e7e7726b6f2be95ea9f3ffc6b9e90a3c2e4387a2a27a680d43a2dabf279836df7e62905789995')
+
+build() {
+  cd ${pkgname}
+
+  if [ "${CARCH}" == "x86_64" ]; then
+    SRCDIR=Linux/x64
+    ./fasm.x64 source/${SRCDIR}/fasm.asm
+  fi
+  mv source/${SRCDIR}/fasm ./fasm
+
+  # tools
+  local s
+  for s in listing prepsrc symbols; do
+    ./fasm tools/libc/${s}.asm ${s}.o
+    gcc -m32 ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} -o ${s} ${s}.o
+  done
+}
+
+package() {
+  cd ${pkgname}
+
+  install -Dm 755 fasm -t "${pkgdir}/usr/bin"
+  # tools
+  local s
+  for s in listing prepsrc symbols; do
+    install -Dm 755 ${s} "${pkgdir}/usr/bin/fasm-${s}"
+  done
+
+  # docs
+  install -Dm 644 ${pkgname}.txt whatsnew.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 examples/elfexe/*.asm -t "${pkgdir}/usr/share/doc/${pkgname}/examples/elfexe"
+  install -Dm 644 examples/elfexe/dynamic/*.asm -t "${pkgdir}/usr/share/doc/${pkgname}/examples/elfexe/dynamic"
+  install -Dm 644 examples/elfexe/dynamic/*.inc -t "${pkgdir}/usr/share/doc/${pkgname}/examples/elfexe/dynamic"
+  install -Dm 644 examples/elfobj/*.asm -t "${pkgdir}/usr/share/doc/${pkgname}/examples/elfobj"
+  install -Dm 644 examples/libcdemo/*.asm -t "${pkgdir}/usr/share/doc/${pkgname}/examples/libcdemo"
+  install -Dm 644 examples/libcdemo/*.inc -t "${pkgdir}/usr/share/doc/${pkgname}/examples/libcdemo"
+  install -Dm 644 license.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: