[arch-commits] Commit in python-param/repos (community-any community-any/PKGBUILD)

[Bruno Pagani]

    Date: Friday, July 26, 2019 @ 08:39:55
  Author: archange
Revision: 492819

archrelease: copy trunk to community-any

Added:
  python-param/repos/community-any/
  python-param/repos/community-any/PKGBUILD
    (from rev 492818, python-param/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: python-param/repos/community-any/PKGBUILD (from rev 492818, python-param/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2019-07-26 08:39:55 UTC (rev 492819)
@@ -0,0 +1,40 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=param
+pkgbase=python-${_pkg,,}
+pkgname=("python-${_pkg,,}" "python2-${_pkg,,}")
+pkgver=1.9.1
+pkgrel=1
+pkgdesc="Make your Python code clearer and more reliable by declaring Parameters"
+arch=(any)
+url="https://param.pyviz.org/"
+license=(BSD)
+makedepends=(python-setuptools python2-setuptools)
+source=("https://files.pythonhosted.org/packages/source/p/${_pkg}/${_pkg}-${pkgver}.tar.gz")
+sha256sums=('b1bd740d436d7734b320db4752f9f747b8a6c0aaf172d7c6146de0f675dc76b5')
+
+prepare() {
+    cp -a ${_pkg}-${pkgver}{,-py2}
+}
+
+build() {
+    cd ${_pkg}-${pkgver}
+    python setup.py build
+
+    cd ../${_pkg}-${pkgver}-py2
+    python2 setup.py build
+}
+
+package_python-param() {
+    cd ${_pkg}-${pkgver}
+    python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+    install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
+package_python2-param() {
+    cd ${_pkg}-${pkgver}-py2
+    python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+    install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}