[arch-commits] Commit in python-colorcet/repos (community-any community-any/PKGBUILD)

[Bruno Pagani]

    Date: Friday, July 26, 2019 @ 11:23:34
  Author: archange
Revision: 492853

archrelease: copy trunk to community-any

Added:
  python-colorcet/repos/community-any/
  python-colorcet/repos/community-any/PKGBUILD
    (from rev 492852, python-colorcet/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-colorcet/repos/community-any/PKGBUILD (from rev 492852, python-colorcet/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2019-07-26 11:23:34 UTC (rev 492853)
@@ -0,0 +1,44 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=colorcet
+pkgbase=python-${_pkg,,}
+pkgname=("python-${_pkg,,}" "python2-${_pkg,,}")
+pkgver=2.0.1
+pkgrel=1
+pkgdesc="Set of useful perceptually uniform colormaps for plotting scientific data"
+arch=(any)
+url="https://colorcet.pyviz.org/"
+license=(BSD)
+makedepends=(python-setuptools python-param python-pyct python2-setuptools python2-param python2-pyct)
+source=("https://files.pythonhosted.org/packages/source/c/${_pkg}/${_pkg}-${pkgver}.tar.gz")
+sha256sums=('ab1d16aba97f54af190631c7777c356b04b53de549672ff6b01c66d716eddff3')
+
+prepare() {
+    cp -a ${_pkg}-${pkgver}{,-py2}
+}
+
+build() {
+    cd ${_pkg}-${pkgver}
+    python setup.py build
+
+    cd ../${_pkg}-${pkgver}-py2
+    python2 setup.py build
+}
+
+package_python-colorcet() {
+    depends=(python-param python-pyct)
+    cd ${_pkg}-${pkgver}
+    python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+    install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
+package_python2-colorcet() {
+    depends=(python2-param python2-pyct)
+    cd ${_pkg}-${pkgver}-py2
+    python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+    mv "${pkgdir}"/usr/bin/colorcet{,2}
+
+    install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}