[arch-commits] Commit in haskell-hspec-contrib/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Jul 27 11:38:37 UTC 2019


    Date: Saturday, July 27, 2019 @ 11:38:36
  Author: felixonmars
Revision: 493189

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hspec-contrib/repos/community-staging-x86_64/
  haskell-hspec-contrib/repos/community-staging-x86_64/PKGBUILD
    (from rev 493188, haskell-hspec-contrib/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-hspec-contrib/repos/community-staging-x86_64/PKGBUILD (from rev 493188, haskell-hspec-contrib/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-07-27 11:38:36 UTC (rev 493189)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hspec-contrib
+pkgname=haskell-hspec-contrib
+pkgver=0.5.1
+pkgrel=19
+pkgdesc="Contributed functionality for Hspec"
+url="https://hspec.github.io/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hspec-core' 'haskell-hunit')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('cc6ee847d7c99b2607c36b2200bf0bc05ce30437110f216f82464069ffdf80a76d836ad7aace3d69a00cf9da4b28d39491a251c6f60401009a6f9c85d20043e0')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list