[arch-commits] Commit in gnome-shell/repos (3 files)

Jan Steffens heftig at archlinux.org
Tue Jun 4 18:49:05 UTC 2019


    Date: Tuesday, June 4, 2019 @ 18:49:04
  Author: heftig
Revision: 354850

archrelease: copy trunk to testing-x86_64

Added:
  gnome-shell/repos/testing-x86_64/
  gnome-shell/repos/testing-x86_64/PKGBUILD
    (from rev 354849, gnome-shell/trunk/PKGBUILD)
  gnome-shell/repos/testing-x86_64/gnome-shell.install
    (from rev 354849, gnome-shell/trunk/gnome-shell.install)

---------------------+
 PKGBUILD            |   51 ++++++++++++++++++++++++++++++++++++++++++++++++++
 gnome-shell.install |    7 ++++++
 2 files changed, 58 insertions(+)

Copied: gnome-shell/repos/testing-x86_64/PKGBUILD (from rev 354849, gnome-shell/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-06-04 18:49:04 UTC (rev 354850)
@@ -0,0 +1,51 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Flamelab <panosfilip at gmail.com
+
+pkgname=gnome-shell
+pkgver=3.32.2+1+g24cb1c1aa
+pkgrel=1
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+arch=(x86_64)
+license=(GPL2)
+depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gnome-settings-daemon
+         gnome-themes-extra gsettings-desktop-schemas libcanberra-pulse libcroco libgdm libsecret
+         mutter nm-connection-editor unzip gstreamer libibus)
+makedepends=(gtk-doc gnome-control-center evolution-data-server gobject-introspection git meson
+             sassc)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome)
+install=gnome-shell.install
+_commit=24cb1c1aabe36b905ce009c2c786f4d70d6184d7  # gnome-3-32
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+  
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  ninja -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+
+  # https://bugs.archlinux.org/task/37412
+  mkdir "$pkgdir/usr/share/gnome-shell/modes"
+}

Copied: gnome-shell/repos/testing-x86_64/gnome-shell.install (from rev 354849, gnome-shell/trunk/gnome-shell.install)
===================================================================
--- testing-x86_64/gnome-shell.install	                        (rev 0)
+++ testing-x86_64/gnome-shell.install	2019-06-04 18:49:04 UTC (rev 354850)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/gnome-shell
+}
+
+post_upgrade() {
+  post_install
+}


More information about the arch-commits mailing list