[arch-commits] Commit in suil/repos (2 files)

David Runge dvzrv at archlinux.org
Sat Jun 8 09:55:22 UTC 2019


    Date: Saturday, June 8, 2019 @ 09:55:22
  Author: dvzrv
Revision: 478224

archrelease: copy trunk to community-staging-x86_64

Added:
  suil/repos/community-staging-x86_64/
  suil/repos/community-staging-x86_64/PKGBUILD
    (from rev 478223, suil/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: suil/repos/community-staging-x86_64/PKGBUILD (from rev 478223, suil/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-06-08 09:55:22 UTC (rev 478224)
@@ -0,0 +1,44 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: speps <speps at aur dot archlinux dot org>
+
+pkgname=suil
+pkgver=0.10.4
+pkgrel=1
+pkgdesc="A lightweight C library for loading and wrapping LV2 plugin UIs"
+arch=('x86_64')
+url="https://drobilla.net/software/suil/"
+license=('custom:ISC')
+makedepends=('gtk2' 'gtk3' 'lv2' 'python' 'qt5-base')
+optdepends=('qt5-base: Qt5 UI wrapping support'
+            'gtk2: GTK+ 2.x UI wrapping support'
+            'gtk3: GTK+ 3.x UI wrapping support')
+source=("https://download.drobilla.net/${pkgname}-${pkgver}.tar.bz2"{,.sig})
+sha512sums=('1f5627541b86cbd8417c0b35b04b73340a3b2dbdd7b04314fdfa82baa8a7b0813c9c9914f805fcf233bcc8011b37efe99a06b6c47a3dda9606d6493edcba434f'
+            'SKIP')
+validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  # remove local call to ldconfig
+  sed -i "/ldconfig/d" wscript
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python waf configure --prefix=/usr
+  python waf build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  python waf install --destdir="${pkgdir}"
+  # license
+  install -vDm 644 COPYING \
+    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  # docs
+  install -t "$pkgdir/usr/share/doc/${pkgname}" \
+    -vDm 644 {AUTHORS,NEWS,PACKAGING,README.md}
+}
+
+# vim:set ts=2 sw=2 et:


More information about the arch-commits mailing list