[arch-commits] Commit in haskell-http-api-data/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Jun 9 11:40:52 UTC 2019


    Date: Sunday, June 9, 2019 @ 11:40:51
  Author: felixonmars
Revision: 478772

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-api-data/repos/community-staging-x86_64/
  haskell-http-api-data/repos/community-staging-x86_64/PKGBUILD
    (from rev 478771, haskell-http-api-data/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-http-api-data/repos/community-staging-x86_64/PKGBUILD (from rev 478771, haskell-http-api-data/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-06-09 11:40:51 UTC (rev 478772)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-api-data
+pkgname=haskell-http-api-data
+pkgver=0.4.1
+pkgrel=4
+pkgdesc="Converting to/from HTTP API data like URL pieces, headers and query parameters."
+url="https://github.com/fizruk/http-api-data"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-attoparsec-iso8601' 'haskell-base-compat'
+         'haskell-cookie' 'haskell-hashable' 'haskell-http-types' 'haskell-tagged'
+         'haskell-time-compat' 'haskell-unordered-containers' 'haskell-uuid-types')
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-doctest' 'haskell-hspec' 'haskell-hunit'
+             'haskell-quickcheck' 'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('62438f9d160a82ed1a6988ae66809281f591e68179bfc52612e49c2cb47042688c949c6177a8cb557102406bd659438522cf9cc82a6b32b69273a2a954958b48')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/nats/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-use-text-show
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list