[arch-commits] Commit in nccl/repos (2 files)

Sven-Hendrik Haase svenstaro at archlinux.org
Tue Jun 11 17:03:39 UTC 2019


    Date: Tuesday, June 11, 2019 @ 17:03:38
  Author: svenstaro
Revision: 480491

archrelease: copy trunk to community-testing-x86_64

Added:
  nccl/repos/community-testing-x86_64/
  nccl/repos/community-testing-x86_64/PKGBUILD
    (from rev 480490, nccl/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: nccl/repos/community-testing-x86_64/PKGBUILD (from rev 480490, nccl/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-06-11 17:03:38 UTC (rev 480491)
@@ -0,0 +1,43 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: Daniel Bermond < yahoo-com: danielbermond >
+
+pkgname=nccl
+pkgver=2.4.7
+pkgrel=1
+pkgdesc='Library for NVIDIA multi-GPU and multi-node collective communication primitives'
+arch=('x86_64')
+url='https://developer.nvidia.com/nccl/'
+license=('BSD')
+depends=('glibc')
+makedepends=('git' 'cuda')
+source=("$pkgname"::"git+https://github.com/NVIDIA/nccl.git#tag=v${pkgver}-1")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "$pkgname"
+
+  # rename BUILDDIR Makefile variable to avoid conflict with makepkg's one
+  local _file
+  local _filelist
+  _filelist="$(find . -type f -exec grep 'BUILDDIR' {} + | awk -F':' '{ print $1 }' | uniq)"
+  for _file in $_filelist
+  do
+    sed -i 's/BUILDDIR/_BUILDPATH/g' "$_file"
+  done
+}
+
+build() {
+  cd "$pkgname"
+
+  make CUDA_HOME='/opt/cuda' src.build
+}
+
+package() {
+  cd "${pkgname}/build"
+
+  install -Dm644 include/nccl.h "${pkgdir}/usr/include/nccl.h"
+  mkdir -p "${pkgdir}/usr/lib"
+  cp -a lib/* "${pkgdir}/usr/lib"
+
+  install -Dm644  "${srcdir}/${pkgname}"/LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list