[arch-commits] Commit in (in-toto in-toto/repos in-toto/trunk in-toto/trunk/PKGBUILD)

[Santiago Torres-Arias]

    Date: Tuesday, June 11, 2019 @ 23:04:23
  Author: sangy
Revision: 480564

addpkg: in-toto 0.3.0-2

Added:
  in-toto/
  in-toto/repos/
  in-toto/trunk/
  in-toto/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: in-toto/trunk/PKGBUILD
===================================================================
--- in-toto/trunk/PKGBUILD	                        (rev 0)
+++ in-toto/trunk/PKGBUILD	2019-06-11 23:04:23 UTC (rev 480564)
@@ -0,0 +1,44 @@
+# Maintainer: Santiago Torres-Arias <santiago at archlinux.org>
+
+pkgname=('in-toto')
+pkgver=0.3.0
+pkgrel=2
+pkgdesc="A framework to secure your software supply chain"
+arch=('any')
+license=('Apache')
+url="https://in-toto.io"
+depends=('python-cryptography'
+    'python-securesystemslib>=0.11.0'
+    'python-iso8601'
+    'python-attrs'
+    'python-dateutil'
+    'python-six'
+    'python-pathspec')
+optdepends=("gnupg: pgp signing/verification")
+makedepends=('python' 'python-setuptools' 'git')
+checkdepends=('python-mock')
+source=("git+https://github.com/${pkgname}/${pkgname}.git?signed#tag=v${pkgver}")
+
+sha256sums=('SKIP')
+
+validpgpkeys=("903BAB73640EB6D65533EFF3468F122CE8162295"
+    # Santiago Torres-Arias (upstream co-maintainer)
+    "8BA69B87D43BE294F23E812089A2AD3C07D962E8"
+    # Lukas Puehringher (upstream maintainer)
+    )
+
+build() {
+    cd "${srcdir}/${pkgname}"
+    python setup.py build
+}
+
+package() {
+    cd "${srcdir}/${pkgname}"
+    python setup.py install --root="$pkgdir" --optimize=1
+    install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
+}
+
+check() {
+    cd "${srcdir}/${pkgname}"
+    python tests/runtests.py
+}