[arch-commits] Commit in babl/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Christian Hesse eworm at archlinux.org
Thu Jun 13 05:34:17 UTC 2019


    Date: Thursday, June 13, 2019 @ 05:34:17
  Author: eworm
Revision: 355990

archrelease: copy trunk to testing-x86_64

Added:
  babl/repos/testing-x86_64/
  babl/repos/testing-x86_64/PKGBUILD
    (from rev 355989, babl/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: babl/repos/testing-x86_64/PKGBUILD (from rev 355989, babl/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-06-13 05:34:17 UTC (rev 355990)
@@ -0,0 +1,43 @@
+# Maintainer: Daniel Isenmann <daniel at archlinux.org>
+
+pkgname=babl
+pkgver=0.1.66
+pkgrel=1
+pkgdesc="Dynamic, any to any, pixel format conversion library"
+arch=(x86_64)
+url="https://gegl.org/babl/"
+license=(LGPL3)
+depends=(glibc)
+makedepends=(git)
+_commit=ebc0f7cf843df52380c00e44f152098332362dad  # tags/BABL_0_1_66^0
+source=("git+https://gitlab.gnome.org/GNOME/babl.git#commit=$_commit")
+sha256sums=('SKIP')
+
+# Don't port to meson until babl's runtime cpu detection works there
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^BABL_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  make -C $pkgname check
+}
+
+package() {
+  DESTDIR="$pkgdir" make -C $pkgname install
+}
+
+# vim:set sw=2 et:


More information about the arch-commits mailing list