[arch-commits] Commit in haskell-persistent-sqlite/repos (2 files)

[Felix Yan]

    Date: Thursday, June 13, 2019 @ 08:39:54
  Author: felixonmars
Revision: 481148

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent-sqlite/repos/community-staging-x86_64/
  haskell-persistent-sqlite/repos/community-staging-x86_64/PKGBUILD
    (from rev 481147, haskell-persistent-sqlite/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-persistent-sqlite/repos/community-staging-x86_64/PKGBUILD (from rev 481147, haskell-persistent-sqlite/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-06-13 08:39:54 UTC (rev 481148)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=persistent-sqlite
+pkgname=haskell-persistent-sqlite
+pkgver=2.9.3
+pkgrel=26
+pkgdesc="Backend for the persistent library using sqlite3"
+url="https://www.yesodweb.com/book/persistent"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'sqlite' 'haskell-aeson' 'haskell-conduit' 'haskell-microlens-th'
+         'haskell-monad-logger' 'haskell-old-locale' 'haskell-persistent' 'haskell-resource-pool'
+         'haskell-resourcet' 'haskell-unliftio-core' 'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-hspec' 'haskell-persistent-template' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('0b31fecbe5486a94b2242f58e529165e646c0dd64d9f8283dd84c6cbde9c0b90f94a730f4443ecb128b9f21a2e94b34d47d12402c6b9d063b6e6eb928c2a46c1')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-build-sanity-exe -fsystemlib -fuse-pkgconfig
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}