[arch-commits] Commit in collectd/repos/community-staging-x86_64 (PKGBUILD service)

[Gaëtan Bisson]

    Date: Saturday, June 15, 2019 @ 19:09:22
  Author: bisson
Revision: 481751

archrelease: copy trunk to community-staging-x86_64

Added:
  collectd/repos/community-staging-x86_64/PKGBUILD
    (from rev 481750, collectd/trunk/PKGBUILD)
  collectd/repos/community-staging-x86_64/service
    (from rev 481750, collectd/trunk/service)

----------+
 PKGBUILD |   74 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 service  |   13 ++++++++++
 2 files changed, 87 insertions(+)

Copied: collectd/repos/community-staging-x86_64/PKGBUILD (from rev 481750, collectd/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-06-15 19:09:22 UTC (rev 481751)
@@ -0,0 +1,74 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Gerhard Brauer <gerhard.brauer at web.de>
+
+pkgname=collectd
+pkgver=5.9.0
+pkgrel=1
+pkgdesc='Daemon which collects system performance statistics periodically'
+url='https://collectd.org/'
+arch=('x86_64')
+license=('GPL')
+
+optdepends=('curl: apache, ascent, curl, nginx, and write_http plugins'
+            'libdbi: dbi plugin'
+            'libesmtp: notify_email plugin'
+            'libgcrypt: encryption and authentication for network plugin'
+            'libmemcached: memcachec plugin'
+            'mariadb-libs: mysql plugin'
+            'systemd-libs: UdevNameAttr option'
+            'iproute2: netlink plugin'
+            'net-snmp: snmp plugin'
+            'libnotify: notify_desktop plugin'
+            'openipmi: ipmi plugin'
+            'liboping: ping plugin'
+            'libpcap: dns plugin'
+            'perl: perl plugin'
+            'postgresql-libs: postgresql plugin'
+            'python: python plugin'
+            'rrdtool: rrdtool and rrdcached plugins'
+            'lm_sensors: lm_sensors and sensors plugins'
+            'libvirt: libvirt plugin'
+            'libxml2: ascent and libvirt plugins'
+            'yajl: curl_json plugin'
+            'libatasmart: smart plugin'
+            'lvm2: lvm plugin'
+            'protobuf-c: write_riemann plugin'
+            'mosquitto: MQTT plugin'
+            'libmicrohttpd: prometheus plugin'
+            'librabbitmq-c: amqp plugin')
+
+makedepends=(${optdepends[@]%:*})
+depends=('libltdl' 'iptables' 'libnsl')
+
+source=("${url}files/${pkgname}-${pkgver}.tar.bz2"
+        'service')
+sha256sums=('7b220f8898a061f6e7f29a8c16697d1a198277f813da69474a67911097c0626b'
+            'e45e261146563b0bf6967c669dff7ac2400f066f0eb4c022ac3fdb0ccadca2f9')
+
+backup=('etc/collectd.conf')
+
+prepare() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	sed 's/ -Werror//g' -i configure
+}
+
+build() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	export MAKEFLAGS='-j1'
+	./configure \
+		--prefix=/usr \
+		--sysconfdir=/etc \
+		--localstatedir=/var \
+		--sbindir=/usr/bin \
+		--with-python=/usr/bin/python \
+		--with-perl-bindings='INSTALLDIRS=vendor'
+	make all
+}
+
+package() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make DESTDIR="${pkgdir}" install
+	rmdir "${pkgdir}/var/run" # FS#30201
+	install -Dm644 ../service "${pkgdir}"/usr/lib/systemd/system/collectd.service
+	install -Dm644 contrib/collectd2html.pl "${pkgdir}"/usr/share/collectd/collectd2html.pl
+}

Copied: collectd/repos/community-staging-x86_64/service (from rev 481750, collectd/trunk/service)
===================================================================
--- service	                        (rev 0)
+++ service	2019-06-15 19:09:22 UTC (rev 481751)
@@ -0,0 +1,13 @@
+[Unit]
+Description=System statistics collection daemon
+After=local-fs.target network.target
+
+[Service]
+Type=forking
+PIDFile=/run/collectdmon.pid
+ExecStart=/usr/bin/collectdmon
+ExecReload=/bin/kill -HUP $MAINPID
+Restart=always
+
+[Install]
+WantedBy=multi-user.target