[arch-commits] Commit in mapnik/repos (3 files)

[Jaroslav Lichtblau]

    Date: Sunday, June 16, 2019 @ 19:28:12
  Author: jlichtblau
Revision: 481879

archrelease: copy trunk to community-staging-x86_64

Added:
  mapnik/repos/community-staging-x86_64/
  mapnik/repos/community-staging-x86_64/PKGBUILD
    (from rev 481878, mapnik/trunk/PKGBUILD)
  mapnik/repos/community-staging-x86_64/mapnik.install
    (from rev 481878, mapnik/trunk/mapnik.install)

----------------+
 PKGBUILD       |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 mapnik.install |   11 +++++++++++
 2 files changed, 66 insertions(+)

Copied: mapnik/repos/community-staging-x86_64/PKGBUILD (from rev 481878, mapnik/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-06-16 19:28:12 UTC (rev 481879)
@@ -0,0 +1,55 @@
+# Maintainer: Jaroslav Lichtblau <svetlemodry at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: David Dent <thewinch at gmail.com>
+# Contributor: orbisvicis <orbisvicis at gmail.com>
+
+pkgname=mapnik
+pkgver=3.0.22
+pkgrel=1
+pkgdesc="Free Toolkit for developing mapping applications and rendering beautiful maps"
+arch=('x86_64')
+url="https://mapnik.org/"
+license=('LGPL')
+depends=('boost-libs' 'icu' 'libpng' 'libjpeg-turbo' 'libtiff' 'freetype2'
+         'libxml2' 'python2' 'proj' 'cairo' 'cairomm' 'python2-cairo'
+         'postgresql-libs' 'postgis' 'gdal' 'curl' 'libtool' 'libwebp')
+makedepends=('scons' 'boost' 'git' 'patch')
+optdepends=('libxslt:         Web Map Service'
+            'python2-lxml:    Web Map Service'
+            'python2-pillow:  Web Map Service'
+            'python-nose:     Web Map Service'
+            'apache:          Web Map Service'
+            'mod_fcgid:       Web Map Service - or:'
+            'mod_wsgi2:       Web Map Service')
+install=$pkgname.install
+source=(https://github.com/$pkgname/$pkgname/releases/download/v$pkgver/$pkgname-v$pkgver.tar.bz2
+        https://github.com/mapnik/mapnik/pull/3892.patch)
+sha256sums=('930612ad9e604b6a29b9cea1bc1de85cf7cf2b2b8211f57ec8b6b94463128ab9'
+            '774a8590b698e9dc2a483e6ff48781ed0400ba06b901f12a1ed50c9114833d47')
+
+prepare() {
+  cd "${srcdir}"/$pkgname-v$pkgver
+  patch -Np1 -i "${srcdir}"/3892.patch
+}
+
+build() {
+  cd "${srcdir}"/$pkgname-v$pkgver
+
+  # http://site.icu-project.org/download/61#TOC-Migration-Issues
+  CXXFLAGS+=' -DU_USING_ICU_NAMESPACE=1'
+
+  PYTHON=python2
+  scons configure \
+    PREFIX="/usr" \
+    INPUT_PLUGINS=all \
+    XMLPARSER=libxml2 \
+    DESTDIR="$pkgdir" \
+    CUSTOM_CXXFLAGS="$CXXFLAGS" \
+    CUSTOM_LDFLAGS="$LDFLAGS"
+  scons $(expr "$MAKEFLAGS" : '.*\(\-j[0-9]\+\)')
+}
+
+package(){
+  cd "${srcdir}"/$pkgname-v$pkgver
+  scons install
+}

Copied: mapnik/repos/community-staging-x86_64/mapnik.install (from rev 481878, mapnik/trunk/mapnik.install)
===================================================================
--- community-staging-x86_64/mapnik.install	                        (rev 0)
+++ community-staging-x86_64/mapnik.install	2019-06-16 19:28:12 UTC (rev 481879)
@@ -0,0 +1,11 @@
+post_install() {
+  /sbin/ldconfig
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}