[arch-commits] Commit in python-pyproj/repos (2 files)
Balló György
bgyorgy at archlinux.org
Wed Jun 19 07:04:03 UTC 2019
Date: Wednesday, June 19, 2019 @ 07:04:03
Author: bgyorgy
Revision: 482310
archrelease: copy trunk to community-staging-x86_64
Added:
python-pyproj/repos/community-staging-x86_64/
python-pyproj/repos/community-staging-x86_64/PKGBUILD
(from rev 482309, python-pyproj/trunk/PKGBUILD)
----------+
PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 55 insertions(+)
Copied: python-pyproj/repos/community-staging-x86_64/PKGBUILD (from rev 482309, python-pyproj/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2019-06-19 07:04:03 UTC (rev 482310)
@@ -0,0 +1,55 @@
+# Maintainer: Jaroslav Lichtblau <svetlemodry at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+
+pkgbase=python-pyproj
+pkgname=('python-pyproj' 'python2-pyproj')
+pkgver=2.2.0
+pkgrel=1
+pkgdesc="Python interfaces to PROJ.4 library"
+arch=('x86_64')
+url="https://github.com/pyproj4/pyproj"
+license=('custom')
+makedepends=('python-setuptools' 'python2-setuptools' 'proj' 'cython' 'cython2')
+source=($pkgname-$pkgver.tar.gz::https://github.com/pyproj4/pyproj/archive/v${pkgver}rel.tar.gz)
+sha256sums=('71ff90b9c2baf6088f54343963b82662758ccfe95c4524d0524c9599a3c7dca5')
+
+prepare() {
+ cd "${srcdir}"
+
+# Remove RPATH
+ sed -i '/runtime_library_dirs=/d' pyproj-${pkgver}rel/setup.py
+
+ cp -a pyproj-${pkgver}rel{,-python2}
+}
+
+build() {
+ cd "${srcdir}"
+
+ export PROJ_DIR=/usr
+
+# Build python 3 module
+ cd pyproj-${pkgver}rel
+ python setup.py build
+
+# Build python 2 module
+ cd ../pyproj-${pkgver}rel-python2
+ python2 setup.py build
+}
+
+package_python-pyproj() {
+ depends=('proj' 'python')
+
+ cd "${srcdir}"/pyproj-${pkgver}rel
+ python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+
+ install -Dm644 LICENSE_proj4 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_python2-pyproj() {
+ depends=('proj' 'python2')
+
+ cd "${srcdir}"/pyproj-${pkgver}rel-python2
+ python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+
+ install -Dm644 LICENSE_proj4 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
More information about the arch-commits
mailing list