[arch-commits] Commit in spice-vdagent/repos (2 files)

[Balló György]

    Date: Wednesday, June 19, 2019 @ 12:11:28
  Author: bgyorgy
Revision: 482344

archrelease: copy trunk to community-testing-x86_64

Added:
  spice-vdagent/repos/community-testing-x86_64/
  spice-vdagent/repos/community-testing-x86_64/PKGBUILD
    (from rev 482343, spice-vdagent/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: spice-vdagent/repos/community-testing-x86_64/PKGBUILD (from rev 482343, spice-vdagent/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-06-19 12:11:28 UTC (rev 482344)
@@ -0,0 +1,37 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: mutantmonkey <aur at mutantmonkey.in>
+
+pkgname=spice-vdagent
+pkgver=0.19.0
+pkgrel=1
+pkgdesc="Spice agent for Linux guests"
+arch=('x86_64')
+url="https://www.spice-space.org/"
+license=('GPL')
+depends=('alsa-lib' 'dbus' 'glib2' 'gtk3' 'libdrm' 'libpciaccess' 'libxfixes' 'libxinerama' 'libxrandr' 'systemd')
+makedepends=('spice-protocol')
+backup=('etc/conf.d/spice-vdagentd')
+source=("https://www.spice-space.org/download/releases/$pkgname-$pkgver.tar.bz2")
+sha256sums=('63a77c611c84f8120519a78a30256e43e159085831ac82de71643db643972f65')
+
+prepare() {
+	cd $pkgname-$pkgver
+	sed -i 's|/etc/sysconfig/spice-vdagentd|/etc/conf.d/spice-vdagentd|
+	        s|/usr/sbin/spice-vdagentd|/usr/bin/spice-vdagentd|' data/spice-vdagentd.service
+	sed -i 's|/etc/sysconfig/spice-vdagentd|/etc/conf.d/spice-vdagentd|' data/spice-vdagentd.1.in
+}
+
+build() {
+	cd $pkgname-$pkgver
+	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin \
+	            --with-session-info=systemd --with-init-script=systemd
+	make
+}
+
+package() {
+	cd $pkgname-$pkgver
+	make DESTDIR="$pkgdir" install
+	rm -r "$pkgdir/var"
+	install -dm755 "$pkgdir/etc/conf.d/"
+	echo 'SPICE_VDAGENTD_EXTRA_ARGS=""' > "$pkgdir/etc/conf.d/spice-vdagentd"
+}