[arch-commits] Commit in falkon/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Thu Jun 20 10:57:44 UTC 2019


    Date: Thursday, June 20, 2019 @ 10:57:43
  Author: arojas
Revision: 356602

archrelease: copy trunk to testing-x86_64

Added:
  falkon/repos/testing-x86_64/
  falkon/repos/testing-x86_64/PKGBUILD
    (from rev 356601, falkon/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: falkon/repos/testing-x86_64/PKGBUILD (from rev 356601, falkon/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-06-20 10:57:43 UTC (rev 356602)
@@ -0,0 +1,41 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=falkon
+pkgver=3.1.0
+pkgrel=5
+pkgdesc="Cross-platform QtWebEngine browser"
+arch=(x86_64)
+url="https://www.falkon.org/"
+license=(GPL3)
+depends=(qt5-webengine qt5-x11extras qt5-svg)
+makedepends=(extra-cmake-modules qt5-tools kio purpose libgnome-keyring pyside2 shiboken2)
+optdepends=('kio: KDE integration' 'purpose: KDE integration' 'libgnome-keyring: gnome keyring integration'
+            'pyside2: Python plugins')
+replaces=(qupzilla)
+source=(https://download.kde.org/stable/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz{,.sig}
+        falkon-pyside-5.12.2.patch::"https://cgit.kde.org/falkon.git/patch/?id=479933e0")
+sha256sums=('ce743cd80c0e2d525a784e29c9b487f73480119b0567f9ce8ef1f44cca527587'
+            'SKIP'
+            'ab7b8c1a8e0e53cb3db2722498f55cb39103d2138f4cf71859384549544074d6')
+validpgpkeys=(3CB7B8416EF6778B409FDC43EBC3FC294452C6D8) # David Rosca <nowrep at gmail.com>
+
+prepare() {
+  mkdir -p build
+
+  cd $pkgname-$pkgver
+  patch -p1 -i ../falkon-pyside-5.12.2.patch # Fix build with PySide 5.12.2
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}


More information about the arch-commits mailing list