[arch-commits] Commit in python-tornado/repos/community-testing-x86_64 (2 files)

Felix Yan felixonmars at archlinux.org
Mon Jun 24 05:56:53 UTC 2019


    Date: Monday, June 24, 2019 @ 05:56:53
  Author: felixonmars
Revision: 483450

archrelease: copy trunk to community-testing-x86_64

Added:
  python-tornado/repos/community-testing-x86_64/PKGBUILD
    (from rev 483448, python-tornado/trunk/PKGBUILD)
Deleted:
  python-tornado/repos/community-testing-x86_64/PKGBUILD

----------+
 PKGBUILD |  134 +++++++++++++++++++++----------------------------------------
 1 file changed, 47 insertions(+), 87 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-06-24 05:56:47 UTC (rev 483449)
+++ PKGBUILD	2019-06-24 05:56:53 UTC (rev 483450)
@@ -1,87 +0,0 @@
-# Maintainer: Felix Yan <felixonmars at archlinux.org>
-# Contributor: Thomas Dziedzic < gostrc at gmail >
-
-pkgbase=python-tornado
-pkgname=('python-tornado' 'python2-tornado')
-pkgver=6.0.2
-pkgrel=1
-pkgdesc='open source version of the scalable, non-blocking web server and tools'
-arch=('x86_64')
-url='http://www.tornadoweb.org/'
-license=('Apache')
-makedepends=('python-setuptools' 'python2-setuptools' 'python2-futures' 'python2-singledispatch'
-             'python2-backports-abc')
-checkdepends=('python-pycurl' 'python2-pycurl' 'python-mock' 'python2-mock' 'python-twisted'
-              'python2-twisted'  'python2-trollius' 'python2-monotonic')
-source=("$pkgbase-$pkgver.tar.gz::https://github.com/tornadoweb/tornado/archive/v$pkgver.tar.gz")
-sha512sums=('5f0678f00776034a6775d2d50206161028bf3798f97a6a40af7ff3f3552eb367bd694ceb578afdec96f60282f851d5bf5091839c25f1b569965017aa418de983')
-
-prepare() {
-  cd "$srcdir"
-  cp -a tornado-$pkgver{,-py2}
-
-  # python -> python2 rename
-  find tornado-$pkgver-py2 -name '*py' -exec sed -e 's_#!/usr/bin/env python_&2_' -i {} \;
-
-  export TORNADO_EXTENSION=1
-}
-
-build() {
-  cd tornado-$pkgver
-  python setup.py build
-
-  cd ../tornado-$pkgver-py2
-  python2 setup.py build
-}
-
-check() {
-  # As of 4.5.3, ignoring test failures about resolving "localhost"
-  (
-    cd tornado-$pkgver
-    python setup.py install --root="$PWD/tmp_install" --optimize=1
-    export PYTHONPATH="$PWD/tmp_install/usr/lib/python3.7/site-packages:$PYTHONPATH"
-    cd tmp_install
-    python -m tornado.test.runtests
-    python -m tornado.test.runtests --ioloop=tornado.platform.select.SelectIOLoop
-    python -m tornado.test.runtests --httpclient=tornado.curl_httpclient.CurlAsyncHTTPClient
-    python -m tornado.test.runtests --ioloop_time_monotonic
-    python -m tornado.test.runtests --ioloop=tornado.platform.twisted.TwistedIOLoop
-    python -m tornado.test.runtests --ioloop=tornado.platform.asyncio.AsyncIOLoop
-    python -m tornado.test.runtests --resolver=tornado.netutil.ThreadedResolver
-  ) || warning "Tests failed"
-
-  (
-    cd tornado-$pkgver-py2
-    python2 setup.py install --root="$PWD/tmp_install" --optimize=1
-    export PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH"
-    cd tmp_install
-    python2 -m tornado.test.runtests
-    python2 -m tornado.test.runtests --ioloop=tornado.platform.select.SelectIOLoop
-    python2 -m tornado.test.runtests --httpclient=tornado.curl_httpclient.CurlAsyncHTTPClient
-    python2 -m tornado.test.runtests --ioloop_time_monotonic
-    python2 -m tornado.test.runtests --ioloop=tornado.platform.twisted.TwistedIOLoop
-    python2 -m tornado.test.runtests --ioloop=tornado.platform.asyncio.AsyncIOLoop
-    python2 -m tornado.test.runtests --resolver=tornado.netutil.ThreadedResolver
-  ) || warning "Tests failed"
-}
-
-package_python-tornado() {
-  depends=('python')
-  optdepends=('python-pycurl: for tornado.curl_httpclient'
-              'python-twisted: for tornado.platform.twisted')
-              # 'python-pycares: an alternative non-blocking DNS resolver'
-
-  cd tornado-$pkgver
-  python setup.py install --root="$pkgdir" --optimize=1
-}
-
-package_python2-tornado() {
-  depends=('python2-futures' 'python2-singledispatch' 'python2-backports-abc')
-  optdepends=('python2-monotonic: enable support for a monotonic clock'
-              'python2-pycurl: for tornado.curl_httpclient'
-              'python2-twisted: for tornado.platform.twisted')
-              # 'python2-pycares: an alternative non-blocking DNS resolver'
-
-  cd tornado-$pkgver-py2
-  python2 setup.py install --root="$pkgdir" --optimize=1
-}

Copied: python-tornado/repos/community-testing-x86_64/PKGBUILD (from rev 483448, python-tornado/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-06-24 05:56:53 UTC (rev 483450)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+
+pkgname=python-tornado
+pkgver=6.0.3
+pkgrel=1
+pkgdesc='open source version of the scalable, non-blocking web server and tools'
+arch=('x86_64')
+url='http://www.tornadoweb.org/'
+license=('Apache')
+depends=('python')
+optdepends=('python-pycurl: for tornado.curl_httpclient'
+            'python-twisted: for tornado.platform.twisted')
+            # 'python-pycares: an alternative non-blocking DNS resolver'
+makedepends=('python-setuptools')
+checkdepends=('python-pycurl' 'python-mock' 'python-twisted')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/tornadoweb/tornado/archive/v$pkgver.tar.gz")
+sha512sums=('8caaa64d14edcb3993dffea3175685d82afb0068a8e8834cbb6eb9e15883fe113bb57cd98d99c25362bef0a6ee2762f2baf24effd645ecd77f035583cc4de756')
+
+export TORNADO_EXTENSION=1
+
+build() {
+  cd tornado-$pkgver
+  python setup.py build
+}
+
+check() {
+  # As of 4.5.3, ignoring test failures about resolving "localhost"
+  (
+    cd tornado-$pkgver
+    python setup.py install --root="$PWD/tmp_install" --optimize=1
+    export PYTHONPATH="$PWD/tmp_install/usr/lib/python3.7/site-packages:$PYTHONPATH"
+    cd tmp_install
+    python -m tornado.test.runtests
+    python -m tornado.test.runtests --ioloop=tornado.platform.select.SelectIOLoop
+    python -m tornado.test.runtests --httpclient=tornado.curl_httpclient.CurlAsyncHTTPClient
+    python -m tornado.test.runtests --ioloop_time_monotonic
+    python -m tornado.test.runtests --ioloop=tornado.platform.twisted.TwistedIOLoop
+    python -m tornado.test.runtests --ioloop=tornado.platform.asyncio.AsyncIOLoop
+    python -m tornado.test.runtests --resolver=tornado.netutil.ThreadedResolver
+  ) || warning "Tests failed"
+}
+
+package() {
+  cd tornado-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}


More information about the arch-commits mailing list