[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Thu Jun 27 07:08:24 UTC 2019


    Date: Thursday, June 27, 2019 @ 07:08:23
  Author: felixonmars
Revision: 484670

addpkg: dns-over-https 2.0.1-1

Added:
  dns-over-https/
  dns-over-https/repos/
  dns-over-https/trunk/
  dns-over-https/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: dns-over-https/trunk/PKGBUILD
===================================================================
--- dns-over-https/trunk/PKGBUILD	                        (rev 0)
+++ dns-over-https/trunk/PKGBUILD	2019-06-27 07:08:23 UTC (rev 484670)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sherlock Holo <sherlockya(at)gmail.com>
+# Contributor: Ariel AxionL <i [at] axionl [dot] me>
+
+pkgname=dns-over-https
+pkgver=2.0.1
+pkgrel=1
+pkgdesc="Client and server software to query DNS over HTTPS, using Google DNS-over-HTTPS protocol"
+url="https://github.com/m13253/dns-over-https"
+arch=('x86_64')
+license=('MIT')
+backup=('etc/dns-over-https/doh-client.conf'
+        'etc/dns-over-https/doh-server.conf')
+provides=('dns-over-https-client' 'dns-over-https-server')
+makedepends=('go-pie' 'golang-golang-x-crypto' 'golang-golang-x-net' 'golang-golang-x-sys' 'git')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/m13253/dns-over-https/archive/v$pkgver.tar.gz")
+sha256sums=('240115da99d54333bda85f785648778cbc1a647f6de9ad0dfb261e0e1cde72be')
+
+build() {
+  mkdir -p $srcdir/go/src
+  export GOPATH="$srcdir/go:/usr/share/gocode"
+
+  cd $srcdir/$pkgname-$pkgver
+  sed -i 's/\/local//g' systemd/doh-{client,server}.service
+
+  go get github.com/BurntSushi/toml github.com/gorilla/handlers github.com/miekg/dns
+  
+  go build -gcflags "all=-trimpath=$PWD" -asmflags "all=-trimpath=$PWD" -ldflags "-w -s -extldflags $LDFLAGS" -v -o client ./doh-client
+  go build -gcflags "all=-trimpath=$PWD" -asmflags "all=-trimpath=$PWD" -ldflags "-w -s -extldflags $LDFLAGS" -v -o server ./doh-server
+}
+
+package() {
+  cd $pkgname-$pkgver
+  install -Dm755 client "$pkgdir"/usr/bin/doh-client
+  install -Dm644 doh-client/doh-client.conf "$pkgdir"/etc/dns-over-https/doh-client.conf
+  install -Dm644 systemd/doh-client.service "$pkgdir"/usr/lib/systemd/system/doh-client.service
+  install -Dm755 NetworkManager/dispatcher.d/doh-client "$pkgdir"/etc/NetworkManager/dispatcher.d/doh-client
+
+  install -Dm755 server "$pkgdir"/usr/bin/doh-server
+  install -Dm644 doh-server/doh-server.conf "$pkgdir"/etc/dns-over-https/doh-server.conf
+  install -Dm644 systemd/doh-server.service "$pkgdir"/usr/lib/systemd/system/doh-server.service
+  install -Dm755 NetworkManager/dispatcher.d/doh-server "$pkgdir"/etc/NetworkManager/dispatcher.d/doh-server
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


More information about the arch-commits mailing list