[arch-commits] Commit in gst-plugins-bad/repos (2 files)

[Maxime Gauduin]

    Date: Friday, June 28, 2019 @ 07:21:09
  Author: alucryd
Revision: 356995

archrelease: copy trunk to staging-x86_64

Added:
  gst-plugins-bad/repos/staging-x86_64/
  gst-plugins-bad/repos/staging-x86_64/PKGBUILD
    (from rev 356994, gst-plugins-bad/trunk/PKGBUILD)

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

Copied: gst-plugins-bad/repos/staging-x86_64/PKGBUILD (from rev 356994, gst-plugins-bad/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-06-28 07:21:09 UTC (rev 356995)
@@ -0,0 +1,72 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gst-plugins-bad
+pkgver=1.16.0
+pkgrel=3
+pkgdesc="GStreamer open-source multimedia framework bad plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(mjpegtools gst-plugins-base-libs curl chromaprint libmms faad2 celt libdca libdvdnav
+         libmodplug libgme wayland libofa openjpeg2 libwebp libsrtp gnutls sbc rtmpdump libgudev
+         libexif libdvdread libvdpau libmpeg2 wildmidi ladspa openal libusb vulkan-icd-loader
+         libfdk-aac faac soundtouch spandsp neon webrtc-audio-processing libdc1394 libmpcdec zvbi
+         openexr libbs2b libnice lcms2 bluez-libs glu srt aom x265 liblrdf libde265
+         gst-plugins-good)
+makedepends=(python gtk-doc git gobject-introspection gtk3 vulkan-headers vulkan-validation-layers
+             librsvg libtiger zbar fluidsynth lilv meson)
+_commit=5fde70bb63a1cbf6f734fb2429e74ffb53126217  # tags/1.16.0^0
+source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-bad.git#commit=$_commit"
+        'gst-common::git+https://gitlab.freedesktop.org/gstreamer/common.git')
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.common.url "$srcdir/gst-common"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D directfb=disabled \
+    -D flite=disabled \
+    -D gsm=disabled \
+    -D iqa=disabled \
+    -D msdk=disabled \
+    -D nvdec=disabled \
+    -D nvenc=disabled \
+    -D opencv=disabled \
+    -D openh264=disabled \
+    -D openmpt=disabled \
+    -D openni2=disabled \
+    -D opensles=disabled \
+    -D sctp=disabled \
+    -D tinyalsa=disabled \
+    -D voaacenc=disabled \
+    -D voamrwbenc=disabled \
+    -D wasapi=disabled \
+    -D wpe=disabled \
+    -D gobject-cast-checks=disabled \
+    -D glib-asserts=disabled \
+    -D glib-checks=disabled \
+    -D package-name="GStreamer Bad Plugins (Arch Linux)" \
+    -D package-origin="https://www.archlinux.org/"
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}