[arch-commits] Commit in python-apispec/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Jun 30 03:48:01 UTC 2019


    Date: Sunday, June 30, 2019 @ 03:48:00
  Author: felixonmars
Revision: 486033

archrelease: copy trunk to community-testing-any

Added:
  python-apispec/repos/community-testing-any/
  python-apispec/repos/community-testing-any/PKGBUILD
    (from rev 486032, python-apispec/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-apispec/repos/community-testing-any/PKGBUILD (from rev 486032, python-apispec/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2019-06-30 03:48:00 UTC (rev 486033)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-apispec
+pkgname=(python-apispec python2-apispec)
+pkgver=2.0.1
+pkgrel=1
+pkgdesc="A pluggable API specification generator. Currently supports the OpenAPI Specification."
+url="https://github.com/marshmallow-code/apispec"
+license=('MIT')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python-tornado' 'python-bottle' 'python-marshmallow'
+              'python-flask' 'python-prance' 'python-yaml' 'python-mock'
+              'python-openapi-spec-validator')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/marshmallow-code/apispec/archive/$pkgver.tar.gz")
+sha512sums=('afc983dc2148071b411d9a61b4f8e433f9cecaddb0c490eab37229a7593790710e81cdc1f49736a4abca9a20972d517750007a5698bce1790cb889590e04859c')
+
+prepare() {
+  cp -a apispec-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/apispec-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/apispec-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd apispec-$pkgver
+  python setup.py pytest
+}
+
+package_python-apispec() {
+  depends=('python')
+  optdepends=('python-yaml: for yaml support'
+              'python-prance: for validation'
+              'python-openapi-spec-validator: for validation')
+
+  cd apispec-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-apispec() {
+  depends=('python2')
+  optdepends=('python2-yaml: for yaml support')
+
+  cd apispec-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}



More information about the arch-commits mailing list