[arch-commits] Commit in opendht/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Sun Jun 30 11:45:34 UTC 2019
Date: Sunday, June 30, 2019 @ 11:45:33
Author: foutrelis
Revision: 486271
archrelease: copy trunk to community-staging-x86_64
Added:
opendht/repos/community-staging-x86_64/
opendht/repos/community-staging-x86_64/PKGBUILD
(from rev 486270, opendht/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: opendht/repos/community-staging-x86_64/PKGBUILD (from rev 486270, opendht/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2019-06-30 11:45:33 UTC (rev 486271)
@@ -0,0 +1,50 @@
+# Maintainer: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=opendht
+epoch=1
+pkgver=1.9.4
+pkgrel=2
+pkgdesc="A C++11 implementation of the Kademlia DHT (Distributed Hash Table)"
+arch=(x86_64)
+url="https://github.com/savoirfairelinux/opendht"
+license=(GPL3)
+depends=(gnutls nettle readline argon2 jsoncpp restbed)
+makedepends=(msgpack-c cmake cython systemd cppunit)
+optdepends=('python: to use the Python bindings')
+source=("${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha256sums=('f94f1400d90b174d7299714634099013b80ab80ec2bc4f574c790c612d859891')
+
+prepare() {
+ mkdir -p build
+}
+
+build() {
+ cd build
+ cmake ../${pkgname}-${pkgver} \
+ -DCMAKE_BUILD_TYPE=None \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DOPENDHT_TESTS=ON \
+ -DOPENDHT_DOCUMENTATION=OFF \
+ -DOPENDHT_STATIC=OFF \
+ -DOPENDHT_SYSTEMD=ON \
+ -DOPENDHT_LTO=ON \
+ -DOPENDHT_TOOLS=ON \
+ -DOPENDHT_INDEX=ON \
+ -DOPENDHT_PYTHON=ON \
+ -DOPENDHT_PROXY_SERVER=ON \
+ -DOPENDHT_PROXY_CLIENT=ON \
+ -DOPENDHT_PUSH_NOTIFICATIONS=ON
+ make
+}
+
+check() {
+ cd build
+ make test
+}
+
+package() {
+ cd build
+ make DESTDIR="${pkgdir}" install
+}
More information about the arch-commits
mailing list