[arch-commits] Commit in knot/repos (2 files)

Jan Steffens heftig at archlinux.org
Mon Mar 4 22:06:07 UTC 2019


    Date: Monday, March 4, 2019 @ 22:06:06
  Author: heftig
Revision: 437653

archrelease: copy trunk to community-staging-x86_64

Added:
  knot/repos/community-staging-x86_64/
  knot/repos/community-staging-x86_64/PKGBUILD
    (from rev 437652, knot/trunk/PKGBUILD)

----------+
 PKGBUILD |   62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

Copied: knot/repos/community-staging-x86_64/PKGBUILD (from rev 437652, knot/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-03-04 22:06:06 UTC (rev 437653)
@@ -0,0 +1,62 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Ondřej Surý <ondrej at sury.org>
+# Contributor: Julian Brost <julian at 0x4a42.net>
+# Contributor: Oleander Reis <oleander at oleander.cc>
+# Contributor: Otto Sabart <seberm[at]gmail[dot]com>
+
+pkgname=knot
+pkgver=2.7.6
+pkgrel=3
+pkgdesc="High-performance authoritative-only DNS server"
+arch=('x86_64')
+url="https://www.knot-dns.cz/"
+license=('GPL3')
+depends=('libedit' 'gnutls' 'liburcu' 'lmdb'
+         'libidn2' 'systemd' 'libcap-ng'
+         'fstrm' 'protobuf-c' 'libmaxminddb')
+backup=('etc/knot/knot.conf')
+source=("https://secure.nic.cz/files/knot-dns/${pkgname}-${pkgver}.tar.xz"{,.asc})
+sha256sums=('a1cb1877f04f7c2549c977c2658cfafd07c7e0e924f8e8aa8d4ae4b707f697a2'
+            'SKIP')
+validpgpkeys=('742FA4E95829B6C5EAC6B85710BB7AF6FEBBD6AB') # Daniel Salzman <daniel.salzman at nic.cz>
+
+build() {
+    cd ${pkgname}-${pkgver}
+
+    ./configure \
+        --prefix=/usr \
+        --sbindir=/usr/bin \
+        --sysconfdir=/etc \
+        --localstatedir=/var/lib \
+        --libexecdir=/usr/lib/knot \
+        --with-rundir=/run/knot \
+        --with-storage=/var/lib/knot \
+        --enable-recvmmsg \
+        --enable-dnstap \
+        --enable-systemd \
+        --enable-reuseport \
+        --disable-silent-rules
+
+    make
+}
+
+check() {
+    cd ${pkgname}-${pkgver}
+    make check
+}
+
+package() {
+    cd ${pkgname}-${pkgver}
+
+    make DESTDIR="${pkgdir}" install
+
+    # Don’t keep those empty dir, manage them with systemd-tmpfiles instead
+    rmdir "${pkgdir}"/{var/{lib/{knot/,},},run/{knot/,}}
+
+    rm "${pkgdir}"/etc/knot/example.com.zone
+    mv "${pkgdir}"/etc/knot/{knot.sample.conf,knot.conf}
+
+    install -Dm644 distro/common/knot.service -t "${pkgdir}"/usr/lib/systemd/system/
+    install -Dm644 distro/arch/knot.tmpfiles.arch "${pkgdir}"/usr/lib/tmpfiles.d/${pkgname}.conf
+    install -Dm644 distro/arch/knot.sysusers "${pkgdir}"/usr/lib/sysusers.d/${pkgname}.conf
+}


More information about the arch-commits mailing list