[arch-commits] Commit in rtkit/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Tuesday, March 5, 2019 @ 19:38:56
  Author: heftig
Revision: 347119

archrelease: copy trunk to testing-x86_64

Added:
  rtkit/repos/testing-x86_64/
  rtkit/repos/testing-x86_64/PKGBUILD
    (from rev 347118, rtkit/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: rtkit/repos/testing-x86_64/PKGBUILD (from rev 347118, rtkit/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-03-05 19:38:56 UTC (rev 347119)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Corrado Primier <bardo at aur.archlinux.org>
+
+pkgname=rtkit
+pkgver=0.12
+pkgrel=1
+pkgdesc="Realtime Policy and Watchdog Daemon"
+arch=(x86_64)
+url="https://github.com/heftig/rtkit"
+license=(GPL3 'custom:BSD')
+depends=(dbus polkit systemd)
+makedepends=(git)
+_commit=4c7e5ca63b1278b41c31b63a4ca5cce331d9db2e  # tags/v0.12^0
+source=("git+https://github.com/heftig/rtkit#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/lib \
+    --with-systemdsystemunitdir=/usr/lib/systemd/system
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir/usr/lib/installed-tests"
+
+  echo 'u rtkit 133 "RealtimeKit" /proc' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
+  sed -ne '4,25p' rtkit.c >"$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}