[arch-commits] Commit in (ambdec ambdec/repos ambdec/trunk ambdec/trunk/PKGBUILD)
David Runge
dvzrv at archlinux.org
Wed Mar 6 22:47:25 UTC 2019
Date: Wednesday, March 6, 2019 @ 22:47:25
Author: dvzrv
Revision: 437941
Adding ambdec.
Added:
ambdec/
ambdec/repos/
ambdec/trunk/
ambdec/trunk/PKGBUILD
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Added: ambdec/trunk/PKGBUILD
===================================================================
--- ambdec/trunk/PKGBUILD (rev 0)
+++ ambdec/trunk/PKGBUILD 2019-03-06 22:47:25 UTC (rev 437941)
@@ -0,0 +1,45 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+pkgname=ambdec
+pkgver=0.7.1
+pkgrel=1
+pkgdesc="An Ambisonic decoder for first and second order"
+arch=('x86_64')
+url="https://kokkinizita.linuxaudio.org/linuxaudio/downloads/index.html"
+license=('GPL2')
+groups=('pro-audio')
+depends=('clxclient' 'clthreads' 'jack')
+makedepends=('gendesk')
+source=("https://kokkinizita.linuxaudio.org/linuxaudio/downloads/${pkgname}-${pkgver}.tar.bz2")
+noextract=()
+sha512sums=('26f945e07a5e3e3a2000f00eede2499fd6a6ba82587a84d1bbd344ac3c6c8b86d74773491c9366d79b3697c926950308b5f8593ad14316eced7155d48c1ace0e')
+
+prepare() {
+ cd "$pkgname-$pkgver"
+ # strip march=native
+ sed -e '/native/d' \
+ -i source/Makefile
+ # XDG desktop file
+ gendesk -n \
+ --pkgname "${pkgname}" \
+ --name "${pkgname}" \
+ --pkgdesc "${pkgdesc}" \
+ --genericname "Ambisonics Audio Renderer" \
+ --categories "AudioVideo;Audio"
+}
+
+build() {
+ cd "$pkgname-$pkgver/source"
+ make PREFIX=/usr
+}
+
+package() {
+ cd "$pkgname-$pkgver/source"
+ make PREFIX=/usr DESTDIR="$pkgdir/" install
+ install -vDm 644 ../{AUTHORS,README} -t "${pkgdir}/usr/share/doc/${pkgname}/"
+ install -vDm 644 ../presets/*.ambdec \
+ -t "${pkgdir}/usr/share/${pkgname}/presets/"
+ install -vDm 644 ../share/*.png \
+ -t "${pkgdir}/usr/share/${pkgname}/"
+ install -vDm 644 "../${pkgname}.desktop" \
+ -t "${pkgdir}/usr/share/applications/"
+}
More information about the arch-commits
mailing list