[arch-commits] Commit in libosinfo/repos (2 files)

[Antonio Rojas]

    Date: Friday, March 8, 2019 @ 19:42:51
  Author: arojas
Revision: 438167

archrelease: copy trunk to community-testing-x86_64

Added:
  libosinfo/repos/community-testing-x86_64/
  libosinfo/repos/community-testing-x86_64/PKGBUILD
    (from rev 438166, libosinfo/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: libosinfo/repos/community-testing-x86_64/PKGBUILD (from rev 438166, libosinfo/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-03-08 19:42:51 UTC (rev 438167)
@@ -0,0 +1,41 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Stefano Facchini <stefano.facchini at gmail.com>
+
+pkgname=libosinfo
+pkgver=1.4.0
+pkgrel=1
+pkgdesc="GObject based library API for managing information about operating systems, hypervisors and the (virtual) hardware devices they can support"
+arch=('x86_64')
+url="https://libosinfo.org/"
+license=('GPL' 'LGPL')
+depends=('glib2' 'libxslt' 'osinfo-db')
+makedepends=('check' 'gobject-introspection' 'libsoup' 'vala' 'gtk-doc')
+source=(https://releases.pagure.org/libosinfo/$pkgname-$pkgver.tar.gz{,.asc})
+validpgpkeys=('DAF3A6FDB26B62912D0E8E3FBE86EBB415104FDF'  # Daniel P. Berrange
+              '09B9C8FF223EF113AFA06A39EE926C2BDACC177B') # Fabiano Fidêncio <fidencio at redhat.com>
+sha256sums=('a29e61a82b1a5727b145403914812273dfa033a0c07a15500078726bb3b84165'
+            'SKIP')
+
+prepare() {
+  cd $pkgname-$pkgver
+  sed -i '/export LC_ALL = C/d' maint.mk
+}
+
+build() {
+  cd $pkgname-$pkgver
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+              --with-usb-ids-path=/usr/share/hwdata/usb.ids \
+              --with-pci-ids-path=/usr/share/hwdata/pci.ids \
+              --enable-gtk-doc
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver
+  make check || :
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}